dynamic AERENDER MP4/PNG + WEBM/WEBP convert

@echo off
setlocal EnableDelayedExpansion

set "scriptPath=%~dp0"
set "Folder=%scriptPath%"
::set "Folder=C:\data_driven_ae_template-1"

set "RenderedFolder=%Folder%\_rendered"

set "outputFolderWebm=%RenderedFolder%\_webm"
set "outputFolderWebp=%RenderedFolder%\_webp"

REM Use all .aep files inside of the scripts location that use the prefix "comp_"
REM ignore files that include blanks (spaces) in their names
for %%i in (%Folder%\comp_*.aep) do (
   echo %%i | findstr " " > nul
      if errorlevel 1 (
         for /f "delims=." %%a in ("%%~ni") do set "compName=%%a"
            set "inputFile=%%i"
            echo !inputFile!
            echo !compName!
            REM thumbnail-export of frame 0 as PNG
            AERENDER -project "!inputFile!" -comp "!compName!" -s 0 -e 0 -RStemplate "Best Settings" -OMtemplate "PNG" -output "%Folder%\_rendered\!compName!_[#].png"
            AERENDER -project "!inputFile!" -comp "!compName!_square" -s 0 -e 0 -RStemplate "Best Settings" -OMtemplate "PNG" -output "%Folder%\_rendered\!compName!_square_[#].png"
            AERENDER -project "!inputFile!" -comp "!compName!_1920" -s 0 -e 0 -RStemplate "Best Settings" -OMtemplate "PNG" -output "%Folder%\_rendered\!compName!_1920_[#].png"
            REM video-export as MP4
            AERENDER -project "!inputFile!" -comp "!compName!" -RStemplate "Best Settings" -mp -continueOnMissingFootage -mem_usage "100" "100" -OMtemplate "MP4" -output "%Folder%\_rendered\!compName!.mp4"
            AERENDER -project "!inputFile!" -comp "!compName!_square" -RStemplate "Best Settings" -mp -continueOnMissingFootage -mem_usage "100" "100" -OMtemplate "MP4" -output "%Folder%\_rendered\!compName!_square.mp4"
            AERENDER -project "!inputFile!" -comp "!compName!_1920" -RStemplate "Best Settings" -mp -continueOnMissingFootage -mem_usage "100" "100" -OMtemplate "MP4" -output "%Folder%\_rendered\!compName!_1920.mp4"
      )
)
REM create output folders for webp and webm if not existing
if not exist "%outputFolderWebp%" mkdir "%outputFolderWebp%"
if not exist "%outputFolderWebm%" mkdir "%outputFolderWebm%"
REM webp conversion
for %%i in (%RenderedFolder%\*.png) do (
    set "inputFile=%%i"
    echo Processing PNG: !inputFile!

    for /f "delims=." %%a in ("%%~ni") do (
        set "name=%%a"
        set "name=!name:~0,-2!"
        REM Strip the last two characters
    )
    echo !name!

    ffmpeg -i "!inputFile!" -y "%outputFolderWebp%\!name!.webp"
)
REM webm conversion
for %%i in (%RenderedFolder%\*.mp4) do (
    set "inputFile=%%i"
    for /f "delims=." %%a in ("%%~ni") do set "name=%%a"
    echo !name!
    ffmpeg -i "!inputFile!" -y -c:v libvpx-vp9 -crf 28 -b:v 0 -b:a 128k -c:a libopus "%outputFolderWebm%\!name!.webm"
)

echo Conversion complete.
::cmd /k
exit