pkgname=google-chrome-dev
pkgver=19.0.1036.7  # Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Dev%20updates
pkgrel=1
pkgdesc="An attempt at creating a safer, faster, and more stable browser (Dev Channel)"
arch=('i686' 'x86_64')
url="http://www.google.com/chrome"
license=('custom:chrome')
depends=('alsa-lib' 'gconf' 'gtk2' 'hicolor-icon-theme' 'libpng12' 'libxslt' 'libxss' 'nss' 'xdg-utils')
optdepends=('gecko-mediaplayer' 'kdebase-kdialog')
provides=("google-chrome=$pkgver")
conflicts=('google-chrome')
install=${pkgname}.install
_channel='unstable'
_verbld=19.0.1036.7-121466

if [ "$CARCH" = "i686" ]; then
    _arch='i386'
    md5sums=('432a38796e32a1d26eeec4f524b392ce')
elif [ "$CARCH" = "x86_64" ]; then
    _arch='x86_64'
    optdepends+=('flashplugin')
md5sums=('a3fb09d3fc13495e4b55fb213ec90b38')
fi


source=("http://dl.google.com/linux/chrome/rpm/stable/${_arch}/google-chrome-${_channel}-${_verbld}.${_arch}.rpm")


package() {
    msg "Preparing install"
    install -d "$pkgdir"/{opt,usr/{bin,share/applications}}
    mv -v opt/google "$pkgdir"/opt
    msg2 "Done preparing!"

    msg "Actual installation"
    ln -sv /opt/google/chrome/google-chrome "$pkgdir/usr/bin/"
    ln -sv /usr/lib/mozilla/plugins "$pkgdir/opt/google/chrome"
    mv -v "$pkgdir/opt/google/chrome/google-chrome.desktop" "$pkgdir/usr/share/applications"

    # Adding man page
    if [ ! -e "$srcdir/usr/share/man/man1/google-chrome.1.gz" ]; then
      gzip -9 "$srcdir/usr/share/man/man1/google-chrome.1"
    fi
    install -Dm644 "$srcdir/usr/share/man/man1/google-chrome.1.gz" "$pkgdir/usr/share/man/man1/google-chrome.1.gz"

    mkdir "$pkgdir/opt/google/chrome/lib"
    cd "$pkgdir/opt/google/chrome/lib"
    ln -svf /usr/lib/libnspr4.so libnspr4.so.0d
    ln -svf /usr/lib/libnss3.so libnss3.so.1d
    ln -svf /usr/lib/libnssutil3.so libnssutil3.so.1d
    ln -svf /usr/lib/libplc4.so libplc4.so.0d
    ln -svf /usr/lib/libplds4.so libplds4.so.0d
    ln -svf /usr/lib/libsmime3.so libsmime3.so.1d
    ln -svf /usr/lib/libssl3.so libssl3.so.1d

    # Symlinking icons to /usr/share/icons/hicolor/
    for i in 16x16 22x22 24x24 32x32 48x48 64x64 128x128 256x256; do
      mkdir -p "$pkgdir/usr/share/icons/hicolor/$i/apps/"
      ln -s /opt/google/chrome/product_logo_${i/x*}.png "$pkgdir/usr/share/icons/hicolor/$i/apps/google-chrome.png"
    done

    # Fixing permissions of chrome-sandbox
    chmod 4755 "$pkgdir/opt/google/chrome/chrome-sandbox"

    msg2 "Installation finished!"
}