pkgbase=('libc++')
pkgname=('libc++' 'libc++abi' 'libc++experimental')
pkgver=3.9.1
pkgrel=1
arch=('i686' 'x86_64')
url="http://libcxx.llvm.org/"
license=('MIT' 'custom:University of Illinois/NCSA Open Source License')
depends=('gcc-libs')
makedepends=(libunwind clang cmake python)
source=(http://llvm.org/releases/$pkgver/llvm-$pkgver.src.tar.xz{,.sig}
        http://llvm.org/releases/$pkgver/libcxx-$pkgver.src.tar.xz{,.sig}
        http://llvm.org/releases/$pkgver/libcxxabi-$pkgver.src.tar.xz{,.sig})
sha256sums=('1fd90354b9cf19232e8f168faf2220e79be555df3aa743242700879e8fd329ee'
            'SKIP'
            '25e615e428f60e651ed09ffd79e563864e3f4bc69a9e93ee41505c419d1a7461'
            'SKIP'
            '920d8be32e6f5574a3fb293f93a31225eeba15086820fcb942155bf50dc029e2'
            'SKIP')
validpgpkeys=(
              # Bill Wendling <void@llvm.org>
              54E3BDE33185D9F69664D22455F5CD70BB5A0569
              # Tom Stellard <tom@stellard.net>
              11E521D646982372EB577A1F8F0871F202119294
              # Hans Wennborg <hans@chromium.org>
              B6C8F98282B944E3B0D5C2530FC3042E345AD05D
)

prepare() {
  mv $srcdir/libcxx-$pkgver.src $srcdir/llvm-$pkgver.src/projects/libcxx
  mv $srcdir/libcxxabi-$pkgver.src $srcdir/llvm-$pkgver.src/projects/libcxxabi
  mkdir build
}

build() {
  cd build
  CC=clang CXX=clang++ cmake \
    -DLIBCXX_ENABLE_EXPERIMENTAL_LIBRARY=On \
    -DLIBCXX_INSTALL_EXPERIMENTAL_LIBRARY=Off \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    $srcdir/llvm-$pkgver.src
  make cxx cxx_experimental
}

package_libc++() {
  pkgdesc='A new implementation of the C++ standard library, targeting C++11.'
  depends=("libc++abi=$pkgver-$pkgrel")
  cd $srcdir/build
  make DESTDIR="$pkgdir" install-libcxx
}

package_libc++abi() {
  pkgdesc='A new implementation of low level support for a standard C++ library'
  cd $srcdir/build
  make DESTDIR="$pkgdir" install-libcxxabi
}

package_libc++experimental() {
  depends=("libc++=$pkgver-$pkgrel")
  pkgdesc='A new implementation of the C++ standard library, targeting \
    C++11 (experimental libraries)'
  cd $srcdir/build
  install -Dm644 lib/libc++experimental.a "$pkgdir"/usr/lib/libc++experimental.a
}