mIRC Alias Pastebin Script

paste {
  sockclose Pastebin
  if (!$1) {
    var %P~ = 1
    while (%P~ <= $cb(0)) && ($len(%Paste) <= 3950) {
      set %Paste %Paste $+ $cb(%P~) $+ $crlf
      inc %P~
    }
  }
  set %Paste api_dev_key=__DEVKEY__&api_option=paste&api_paste_code= $+ $regsubex($iif(!$1,%Paste,$1-),/([ `@#$%^&\+=\[\]{}\\|;'",<>\/\?])/g,% $+ $base($asc(\t),10,16))
  sockopen Pastebin pastebin.com 80
}

on *:SOCKOPEN:Pastebin: {
  sockwrite -n Pastebin POST /api/api_post.php HTTP/1.1
  sockwrite -n Pastebin Host: pastebin.com
  sockwrite -n Pastebin Content-Type: application/x-www-form-urlencoded
  sockwrite -n Pastebin Content-length: $len(%Paste)
  sockwrite Pastebin $crlf
  sockwrite Pastebin %Paste
}

on *:SOCKREAD:Pastebin: {
  var %P
  sockread %P
  while ($sockbr) {
    if (http://pastebin.com/ isin %P) || (Bad API request isin %P) {
      $iif(http://pastebin.com/ isin %P,clipboard %P)
      echo 4 -ag %P
      unset %Paste
      sockclose Pastebin
      return
    }
    sockread %P
  }
}