Digital Light Wand + LCD + SD + HL1606 + BMP direct

//
// Arduino Digital Light Wand + SD + LCD V1.05 for HL1606 strip
// Is0-Mick 2012
//
//
// This version supports direct reading of a 24bit BMP from the SD card.
// You need to rotate the image 90 degrees right, due to lack of memory / speed to process
// this on the fly...

// Fixed the SD init problem (removing card, trying to send a file (which fails) now re-inits the card.
// Backlight now fades out, instead of just switching off.
//
//


//
// Changed one of the original values of the shields key values, as it was thinking you were pressing a different
// button sometimes, so changed the 535 value to 580 which seems to fix that :)
//
// Added code for an external switch to show the bitmap so you don't have fiddle with the small button on the shield
// Pins are defined as aux button. I pulled one low as a GND, and the other is the trigger.(pins 44,45 currently)



#include <SD.h>
#include <LEDStrip.h>
#include <LiquidCrystal.h>

#define SIPIN 30
#define DIPIN 31
#define CLKPIN 32
#define LATCHPIN 33
LEDStrip mystrip(DIPIN,SIPIN,LATCHPIN,CLKPIN);

#define STRIP_LENGTH 48
#define BACKLIGHT 10
byte BL = B10000000; // Black / Off
#define SDssPin 53  //SD card CS pin
int frameDelay = 10; // default for the frame delay
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);  //Init the LCD

//BacklightControl to save battery Life
boolean BackLightTimer = false;
int BackLightTimeout = 2000;
int BackLightTemp =  BackLightTimeout;

//Stuff for the Keypad
//int adc_key_val[5] ={
//  30, 150, 360, 535, 760 };

int adc_key_val[5] ={
  30, 150, 360, 560, 760 };
int NUM_KEYS = 5;
int adc_key_in;
int key=-1;
int oldkey=-1;

//AuxButton is a seperate button to send the image.
int AuxButton = 44;
int AuxButtonGND = 45;

File root;
File dataFile;
String m_CurrentFilename = "";
int m_FileIndex = 0;
int m_NumberOfFiles = 0;
String m_FileNames[200]; //yep this is bad, but unless you are going to have over 200 images on your lightwand..

long buffer[STRIP_LENGTH];
char tmpbuffer[20];
long lCntr[1];

struct bitmapblock {
  byte len;
  byte r;
  byte g;
  byte b;
}
mybitmapblock;

char buf[4];
int fileVersion;
uint32_t bitmapOffset;
int bitmapHeight;
uint32_t bitmapWidth;
int StartDelay;
int EndDelay;
int StrobeOn;
int StrobeOff;
byte VReversed;
byte HReversed;

//Colour weights for the HL1606..
uint8_t HL1606highred = 100;
uint8_t HL1606highgreen = 100;
uint8_t HL1606highblue = 100;
uint8_t HL1606lowred = 20;
uint8_t HL1606lowgreen = 20;
uint8_t HL1606lowblue = 20;



void setup()
{
  Serial.begin(115200);
  pinMode(AuxButton, INPUT);
  digitalWrite(AuxButton,HIGH);
  pinMode(AuxButtonGND, OUTPUT);
  digitalWrite(AuxButtonGND,LOW);
  setupLEDs();
  setupLCDdisplay();
  setupSDcard();
  BackLightOn();
}

void setupLEDs()
{
  ClearStrip(100);
}

void setupLCDdisplay()
{
  lcd.begin(16,2);
  lcd.print("*** DLW V.05 ***");
  lcd.setCursor(0, 1);
  lcd.print("Initializing...");
  delay(1000);
  lcd.clear();
}

void setupSDcard()
{
  pinMode(SDssPin, OUTPUT);

  while (!SD.begin(SDssPin)) {
    BackLightOn();
    lcd.print("SD init failed!");
    delay(1000);
    lcd.clear();
    delay(500);
  }
  lcd.clear();
  lcd.print("SD init done.");
  delay(1000);
  root = SD.open("/");
  lcd.clear();
  lcd.print("Scanning files");
  delay(500);
  GetFileNamesFromSD(root);
  isort(m_FileNames, m_NumberOfFiles);
  m_CurrentFilename = m_FileNames[0];
  DisplayCurrentFilename();

}

void latchanddelay(int dur)
{
  mystrip.latch();
  delay(dur);
}

void ClearStrip(int duration)
{
  int x;
  for(x=0;x<STRIP_LENGTH;x++)
  {
    mystrip.pushCmd(BL);
  }
  latchanddelay(duration);
}

void MultiPush(int Cmd, int Cnt) {
  while(Cnt-->0) mystrip.pushCmd(Cmd);
}

int ReadKeypad()
{
  adc_key_in = analogRead(0);    // read the value from the sensor
  digitalWrite(13, HIGH);
  key = get_key(adc_key_in);                // convert into key press
  Serial.print("key read = ");
  Serial.println(adc_key_in,DEC);

  if (key != oldkey)                    // if keypress is detected
  {
    delay(50);      // wait for debounce time
    adc_key_in = analogRead(0);    // read the value from the sensor
    key = get_key(adc_key_in);              // convert into key press
    if (key != oldkey)
    {
      oldkey = key;
      if (key >=0){
        return key;
      }
    }
  }
  return key;
}


// Convert ADC value to key number
int get_key(unsigned int input)
{
  int k;
  for (k = 0; k < NUM_KEYS; k++)
  {
    if (input < adc_key_val[k])
    {
      return k;
    }
  }
  if (k >= NUM_KEYS)
    k = -1;     // No valid key pressed
  return k;
}


//The Main menu starts here...
void loop()
{
  int keypress = ReadKeypad();
  if ( keypress == 1) //up key (step up through the filenames)
  {
    BackLightOn();
    if (m_FileIndex > 0)
    {
      m_FileIndex--;
    }
    else
    {
      m_FileIndex = m_NumberOfFiles -1; //wrap round to the last file
    }

    DisplayCurrentFilename();
    delay(500);
  }

  if ( keypress == 2) //down key (step down through the filenames)
  {
    BackLightOn();
    if (m_FileIndex < m_NumberOfFiles -1)
    {
      m_FileIndex++;
    }
    else
    {
      m_FileIndex = 0;//wrap round to the 1st file again
    }
    DisplayCurrentFilename();
    delay(500);
  }
  Serial.print(digitalRead(AuxButton),DEC);

  if ((keypress == 4) || (digitalRead(AuxButton) == LOW))//select key (send out the selected file)
  {
    SendFile(m_CurrentFilename);
  }

  if(keypress == 0) //right key (frame delay +)
  {
    BackLightOn();
    if (frameDelay < 200)
    {
      frameDelay+=5;
    }
    ShowFrameDelay();
  }

  if(keypress == 3)//left key (frame delay -)
  {
    BackLightOn();
    if (frameDelay > 5)
    {
      frameDelay-=5;
    }
    ShowFrameDelay();
  }

  if (BackLightTimer == true) BackLightTime();

}

void BackLightOn()
{
  analogWrite(BACKLIGHT,255);
  BackLightTimer = true;
  BackLightTemp =  BackLightTimeout;
}

void BackLightTime()
{
  if ((BackLightTemp <= 255) && (BackLightTemp >= 0))
  {
    analogWrite(BACKLIGHT,BackLightTemp);
    delay(1);
  }

  if (BackLightTemp <= 0)
  {
    BackLightTimer = false;
    BackLightTemp =  BackLightTimeout;
    analogWrite(BACKLIGHT,0);
  }
  else
  {
    BackLightTemp --;
    delay(1);
  }
}

void ShowFrameDelay()
{
  lcd.clear();
  lcd.print("Frame delay:");
  lcd.setCursor(0,1);
  lcd.print(frameDelay);
  delay(500);
  DisplayCurrentFilename();
}


void SendFile(String Filename)
{
  lcd.clear();
  lcd.print("Sending File");
  lcd.setCursor(0, 1);
  lcd.print(Filename);
  char temp[14];
  Filename.toCharArray(temp,14);

  dataFile = SD.open(temp);

  // if the file is available send it to the LED's
  if (dataFile)
  {
    ReadTheFile();
    dataFile.close();
    ClearStrip(100);
  }
  else
  {
    lcd.clear();
    lcd.print("  Error reading");
    lcd.setCursor(4, 1);
    lcd.print("file");
    BackLightOn();
    delay(1000);
    lcd.clear();
    setupSDcard();//try to re-init the SD card...(this was failing, but a fix can be done below)
    //In the SD.CPP in the BEGIN class which starts
    // boolean SDClass::begin(uint8_t csPin) {
    //
    //it needs the line below to be added
    //
    // if (root.isOpen()) root.close(); // allows repeated calls
    //
    // Just before the line
    // return card.init(SPI_HALF_SPEED, csPin) &&
    //
    //


    return;
  }
  DisplayCurrentFilename();
}

void DisplayCurrentFilename()
{
  m_CurrentFilename = m_FileNames[m_FileIndex];
  lcd.clear();
  lcd.print(m_CurrentFilename);
}

void GetFileNamesFromSD(File dir)
{
  int fileCount = 0;
  String CurrentFilename = "";
  while(1)
  {
    File entry =  dir.openNextFile();
    if (! entry) {
      // no more files
      m_NumberOfFiles = fileCount;
      break;
    }
    else
    {
      if (entry.isDirectory()) {
        //GetNextFileName(root);
      }
      else {
        CurrentFilename = entry.name();
        if (CurrentFilename.endsWith(".bmp") || CurrentFilename.endsWith(".BMP") )//find files with our extension only
        {
          m_FileNames[fileCount] = entry.name();
          fileCount++;
        }
      }
    }
  }
}


uint32_t readLong()
{
  uint32_t retValue;
  byte incomingbyte;

  incomingbyte=readByte();
  retValue=(uint32_t)((byte)incomingbyte);

  incomingbyte=readByte();
  retValue+=(uint32_t)((byte)incomingbyte)<<8;

  incomingbyte=readByte();
  retValue+=(uint32_t)((byte)incomingbyte)<<16;

  incomingbyte=readByte();
  retValue+=(uint32_t)((byte)incomingbyte)<<24;

  return retValue;
}

uint16_t readInt()
{
  byte incomingbyte;
  uint16_t retValue;

  incomingbyte=readByte();
  retValue+=(uint16_t)((byte)incomingbyte);

  incomingbyte=readByte();
  retValue+=(uint16_t)((byte)incomingbyte)<<8;

  return retValue;
}

int readByte()
{
  int retbyte=-1;
  while(retbyte<0) retbyte= dataFile.read();
  return retbyte;
}


void writeRGB(uint8_t Red,uint8_t Green,uint8_t Blue)
{
  byte colorByte = 128;

  if (Blue > HL1606highblue) colorByte |= 1; //Bright Blue
  else if (Blue > HL1606lowblue) colorByte |= 2; //Dim Blue
  if (Red > HL1606highred) colorByte |= 4; //Bright Red
  else if (Red > HL1606lowred) colorByte |= 8; //Dim Red
  if (Green > HL1606highgreen) colorByte |= 16; //Bright Green
  else if (Green > HL1606lowgreen) colorByte |= 32; //Dim Green
  mystrip.pushCmd(colorByte);
}



void ReadTheFile()
{
#define MYBMP_BF_TYPE           0x4D42
#define MYBMP_BF_OFF_BITS       54
#define MYBMP_BI_SIZE           40
#define MYBMP_BI_RGB            0L
#define MYBMP_BI_RLE8           1L
#define MYBMP_BI_RLE4           2L
#define MYBMP_BI_BITFIELDS      3L



  uint16_t bmpType = readInt();
  uint32_t bmpSize = readLong();
  uint16_t bmpReserved1 = readInt();
  uint16_t bmpReserved2 = readInt();
  uint32_t bmpOffBits = readLong();
  bmpOffBits = 54;

  Serial.println("bmpType = ");
  Serial.println(bmpType,HEX);

  Serial.println("bmpSize");
  Serial.println(bmpSize,DEC);

  Serial.println("bmpReserved1");
  Serial.println(bmpReserved1,DEC);

  Serial.println("bmpReserved2");
  Serial.println(bmpReserved2,DEC);


  Serial.println("bmpOffBits");
  Serial.println(bmpOffBits,DEC);

  /* Check file header */
  if (bmpType != MYBMP_BF_TYPE || bmpOffBits != MYBMP_BF_OFF_BITS)
  {
    lcd.setCursor(0, 0);
    lcd.print("not a bitmap");
    delay(1000);
    return;
  }

  /* Read info header */
  uint32_t imgSize = readLong();
  uint32_t imgWidth = readLong();
  uint32_t imgHeight = readLong();
  uint16_t imgPlanes = readInt();
  uint16_t imgBitCount = readInt();
  uint32_t imgCompression = readLong();
  uint32_t imgSizeImage = readLong();
  uint32_t imgXPelsPerMeter = readLong();
  uint32_t imgYPelsPerMeter = readLong();
  uint32_t imgClrUsed = readLong();
  uint32_t imgClrImportant = readLong();


  Serial.println("bitmap height");
  Serial.println(imgHeight,DEC);
  Serial.println("bitmap Width");
  Serial.println(imgWidth,DEC);
  Serial.println("bitmap bpp");
  Serial.println(imgBitCount,DEC);

  /* Check info header */
  if( imgSize != MYBMP_BI_SIZE || imgWidth <= 0 ||
    imgHeight <= 0 || imgPlanes != 1 ||
    imgBitCount != 24 || imgCompression != MYBMP_BI_RGB ||
    imgSizeImage == 0 )
  {
    lcd.setCursor(0, 0);
    lcd.print("Unsupported");
    lcd.setCursor(0, 1);
    lcd.print("Bitmap Use 24bpp");
    delay(1000);
    return;
  }

  int displayWidth = imgWidth;
  if (imgWidth > STRIP_LENGTH)
  {
    displayWidth = STRIP_LENGTH;//only display the number of led's we have
  }


  /* compute the line length */
  uint32_t lineLength = imgWidth * 3;
  if ((lineLength % 4) != 0)
    lineLength = (lineLength / 4 + 1) * 4;

  Serial.println("Line Length");
  Serial.println(lineLength,DEC);

  int x = 0;
  for(int y=imgHeight;y>0 ;y--) {

    int bufpos=0;
    for(int x=displayWidth;x>0  ;x--) {

      uint32_t offset = (MYBMP_BF_OFF_BITS + (((y-1)* lineLength) + (x*3))) ;

      /*
      Serial.println("offset");
       Serial.println(offset,HEX);
       Serial.println("X = ");
       Serial.println(x,DEC);
       Serial.println("Y = ");
       Serial.println(y,DEC);
       */

    dataFile.seek(offset);

    int g=((readByte() & 0xff)>>1);
    int b=((readByte() & 0xff)>>1);
    int r=((readByte() & 0xff)>>1);

     writeRGB(r,g,b);
    }
    latchanddelay(frameDelay);

  }
  Serial.println("Finished");
  ClearStrip(100);
}

//sort the filenames in alphabetical order
void isort(String *filenames, int n)
{
  for (int i = 1; i < n; ++i)
  {
    String j = filenames[i];
    int k;
    for (k = i - 1; (k >= 0) && (j < filenames[k]); k--)
    {
      filenames[k + 1] = filenames[k];
    }
    filenames[k + 1] = j;
  }
}