Molden PKGBUILD (updated)

pkgname=molden
pkgver=5.0
pkgrel=4
changelog=molden.changelog
pkgdesc="Z-matrix molecular builder and viewer of quantum chemical calculations"
arch=('i686' 'x86_64')
url="http://www.cmbi.ru.nl/molden/molden.html"
license=('custom')
depends=('mesa' 'libxmu')
makedepends=('gcc-fortran')
source=($pkgname.desktop)
md5sums=('d49d3dc4b7b3a449bb48c48a679d10b6')

build() {
  cd "$srcdir"

  _tarball="ftp://ftp.cmbi.ru.nl/pub/molgraph/molden/$pkgname$pkgver.tar.gz"

  # download source code (tarball always has a different md5 sum)
  if [[ ! -f $pkgname$pkgver.tar.gz ]]; then
    curl $_tarball -o $pkgname$pkgver.tar.gz
  fi

  rm -rf $pkgname$pkgver
  bsdtar -xf $pkgname$pkgver.tar.gz
  cd $pkgname$pkgver

  # make
  mv -f CopyRight LICENSE
  make molden gmolden ambfor/{ambfor,ambmd}
}

package() {
  cd "$srcdir"/$pkgname$pkgver

  # install binaries
  install -m755 -d "$pkgdir"/usr/bin
  install -m755 -t "$pkgdir"/usr/bin molden gmolden ambfor/{ambfor,ambmd}

  # install licenses and .desktop file
  install -m755 -d "$pkgdir"/usr/share/{licenses/$pkgname,applications}
  install -m644 -t "$pkgdir"/usr/share/licenses/$pkgname {COMMERCIAL_,}LICENSE
  install -m644 -t "$pkgdir"/usr/share/applications ../$pkgname.desktop
}