# Contributor: mangus 
### requires only Qt as a dependency. 
###The only drawback is that Marble-Qt doesn't provide the whole functionality of Marble 
###  (e.g. the settings dialog or automatic map download via "GHNS")
pkgname=marble
pkgver=1.3.0
_kver=4.8.1
pkgrel=2
pkgdesc="A generic geographical map widget - qt version"
arch=('i686' 'x86_64')
url="http://edu.kde.org/marble"
license=('LGPL')
depends=('qt' 'openssl' 'qtwebkit')
makedepends=('cmake') # 'gpsd')
optdepends=("gpsd: GPS daemon and library to support USB/serial GPS devices")
source=(http://download.kde.org/stable/${_kver}/src/marble-${_kver}.tar.bz2)
md5sums=('438bb6bfae109105b49adcb6eafd7339')
install=marble.install
conflicts=('kdeedu-marble' 'marble-git')

build() {
  cd  ${srcdir}

  if [[ -d ${srcdir}/build ]]; then
    msg "Cleaning the previous build directory..."
    rm -rf ${srcdir}/build 
  fi
  mkdir ${srcdir}/build
  cd ${srcdir}/build
  cmake ${srcdir}/${pkgname}-${_kver} -DCMAKE_INSTALL_PREFIX=/usr  \
			-DCMAKE_BUILD_TYPE=Release -DQTONLY=ON
  make
}
package() {
  cd ${srcdir}/build
  make DESTDIR=${pkgdir} install
}