# Maintainer : Nicolas Pouillard <nicolas(dot)pouillard(at)gmail(dot)com>
# Contributor: Sylvester Johansson <scj(at)archlinux(dot)us>
# Contributor: Sergei Leebdev <superbobry@gmail.com>

pkgname=ocaml-bin-prot
pkgver=1.3.1
pkgrel=1
pkgdesc="binary protocol generator for OCaml"
arch=('i686' 'x86_64')
url="http://www.ocaml.info/home/ocaml_sources.html"
license=('LGPL')
depends=('ocaml' 'ocaml-type-conv')
source=(http://www.janestreet.com/ocaml/bin_prot-$pkgver.tar.gz)
options=(!strip !makeflags)
md5sums=('6ed3471d26ede09250cbcef21f9fb966')
install=ocaml-bin-prot.install

build () {
  cd "$srcdir/bin_prot-$pkgver"
  ocaml setup.ml -configure --prefix /usr --destdir ${pkgdir} --disable-tests
  ocaml setup.ml -build || return 1
}

package () {
  cd "$srcdir/bin_prot-$pkgver"

  OCAMLFIND_DESTDIR="${pkgdir}$(ocamlfind printconf destdir)"

  mkdir -p "${OCAMLFIND_DESTDIR}"
  OCAMLFIND_LDCONF=ignore OCAMLFIND_DESTDIR=$OCAMLFIND_DESTDIR ocaml setup.ml -install || return 1
  install -Dm 644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: