pkgname=freetype2-infinality-git
pkgver=20110610
pkgrel=1
pkgdesc="TrueType font rendering library with infinality patch; git version"
arch=(i686 x86_64)
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('zlib')
conflicts=('freetype2')
provides=("freetype2=$pkgver")
options=('!libtool')
source=(http://www.infinality.net/files/infinality-settings.sh
        http://www.infinality.net/files/freetype-add-subpixel-hinting-infinality-20110604-1.patch
        http://www.infinality.net/files/freetype-enable-subpixel-hinting-infinality-20100909-1.patch
        http://www.infinality.net/files/freetype-entire-infinality-patchset-20110604-1.patch
        http://aoliynik-overlay.googlecode.com/svn-history/r361/trunk/media-libs/freetype/files/freetype-2.3.2-enable-valid.patch)
md5sums=('75b5be731bdeb3616aacdbf328c3b414'
	 'ded8954240034a1e6ab2b2115b3ddb8f'
	 'a88b1a66da44a90c1fdcdeaa39a2dc09'
	 'c3428e393be31d8e4089452135b1ae46'
	 '90217c5567fba0617d2bec4003aeadd9')

_gitroot='git://git.sv.nongnu.org/freetype/freetype2.git'
_gitname='freetype2'

build() {
  cd "${srcdir}"
  
  if [[ -d "${_gitname}" ]]; then
    cd "${_gitname}"
    git pull
  else
    git clone "${_gitroot}" "${_gitname}" && cd "${_gitname}"
  fi

  patch -Np1 -i "${srcdir}/freetype-add-subpixel-hinting-infinality-20110604-1.patch"
  patch -Np1 -i "${srcdir}/freetype-enable-subpixel-hinting-infinality-20100909-1.patch"
  patch -Np1 -i "${srcdir}/freetype-entire-infinality-patchset-20110604-1.patch"
  patch -Np1 -i "${srcdir}/freetype-2.3.2-enable-valid.patch"

  sh ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${_gitname}"

  make DESTDIR="${pkgdir}" install
  install -D -T "${srcdir}/infinality-settings.sh" "${pkgdir}/etc/profile.d/infinality-settings.sh"
}