if (checkalias dfov) [] [alias dfov $fov]
if (checkalias zoominrate) [] [alias zoominrate 250]
if (checkalias zoomoutrate) [] [alias zoomoutrate 125]
if (checkalias zoomfov) [] [alias zoomfov 75]
if (checkalias zoomcrosshair) [] [alias zoomcrosshair 17]
if (checkalias zoomsensscale) [] [alias zoomsensscale .65]

alias zoomingin 0
alias zoomingout 0

alias smoothzoom [
if (= (curweapon) 5) [altaction_5] [
getfov = $fov
getsens = $sensitivity
cchs = $crosshairsize
alias zoominstarttime (millis)
alias zoomingin 1
zoominloop
sensitivity (*f $zoomsensscale (*f $getsens (divf $fov $getfov)))
crosshairsize $zoomcrosshair
onrelease [
alias zoomoutstarttime (millis)
alias zoomingout 1
zoomoutloop
sensitivity $getsens
crosshairsize $cchs]] []]

alias zoominloop [
if $zoomingin [
  alias newfov (-f $fov (*f (-f $dfov $zoomfov) (divf (-f (millis) $zoominstarttime) $zoominrate)))
  if (>=f $newfov $zoomfov) [fov $newfov] [fov $zoomfov; alias zoomingin 0]
  sleep 0 [zoominloop]] []]

alias zoomoutloop [
if $zoomingout [
  alias newfov (+f $fov (*f (-f $dfov $zoomfov) (divf (-f (millis) $zoomoutstarttime) $zoomoutrate)))
  if (<=f $newfov $dfov) [fov $newfov] [fov $dfov; alias zoomingout 0]
sleep 0 [zoomoutloop]] []]

newmenu "Smooth-Zoom"
menuitemtextinput [Default FOV (where FOV rests): ] [result $dfov] [alias dfov $arg1] 3
menuitemtextinput [Zoomed FOV (extent to which FOV zooms): ] [result $zoomfov] [alias zoomfov $arg1] 3
menuitemtextinput [Zoom-in rate (higher is slower): ] [result $zoominrate] [alias zoominrate $arg1] 6
menuitemtextinput [Zoom-out rate (higher is slower): ] [result $zoomoutrate] [alias zoomoutrate $arg1] 6
menuitemtextinput [Zoom crosshair size: ] [result $zoomcrosshair] [alias zoomcrosshair $arg1] 1
menuitemtextinput [Zoom sensitivity scale: ] [result $zoomsensscale] [alias zoomsensscale $arg1] 3
menuitem [                Apply Now!                ] [closemenu]

alias smoothmenu [showmenu "Smooth-Zoom"]