# Contributor: figue <ffigue at gmail>
# Contributor (Parabola): fauno <fauno@kiwwwi.com.ar>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com> 

pkgname=icecat
pkgver=3.6.4
_pkgver=3.6.4
pkgrel=1
_xulver=1.9.2.6
pkgdesc="GNU version of the Firefox browser"
arch=(i686 x86_64)
url="http://www.gnu.org/software/gnuzilla/"
license=('GPL2' 'MPL' 'LGPL')
depends=('xulrunner=1.9.2.6' 'desktop-file-utils' 'mime-types' 'shared-mime-info')
makedepends=('zip' 'libgnomeui>=2.22.1' 'python' 'wireless_tools' 'autoconf')
provides=('firefox')
install=icecat.install
source=(http://ftp.gnu.org/gnu/gnuzilla/${_pkgver}/${pkgname}-${_pkgver}.tar.xz
        mozconfig
        icecat.desktop
        icecat-safe.desktop
        mozilla-firefox-1.0-lang.patch
	xulrunner-copy-stub.patch)

build() {
  ICECATDIR="/usr/lib/${pkgname}-${pkgver}" && export ICECATDIR

  cd "${srcdir}/${pkgname}-${_pkgver}/"
  patch -Np1 -i "${srcdir}/mozilla-firefox-1.0-lang.patch" || return 1
  patch -Np0 -i "${srcdir}/xulrunner-copy-stub.patch" || return 1

  cp "${srcdir}/mozconfig" .mozconfig
  unset CFLAGS
  unset CXXFLAGS

  export LDFLAGS="-Wl,-rpath,/usr/lib/${pkgname}-${pkgver}/"

  make -j1 -f client.mk build MOZ_MAKE_FLAGS="${MAKEFLAGS}" || return 1
  make -j1 DESTDIR="${pkgdir}" install || return 1

  cd ${pkgdir}/${ICECATDIR}
  ln -s ${pkgname} firefox
  ln -s ${pkgname}-bin firefox-bin
  cd ..
  ln -s ${ICECATDIR} icecat

  install -m755 -d ${pkgdir}/usr/share/applications
  install -m755 -d ${pkgdir}/usr/share/pixmaps
  install -m644 ${srcdir}/${pkgname}-${_pkgver}/browser/branding/unofficial/default48.png ${pkgdir}/usr/share/pixmaps/icecat.png || return 1
  install -m644 ${srcdir}/icecat.desktop ${pkgdir}/usr/share/applications/ || return 1
  install -m644 ${srcdir}/icecat-safe.desktop ${pkgdir}/usr/share/applications/ || return 1

  ##copy default prefs manually, icecat fails to start otherwise
  cp -rf ${srcdir}/${pkgname}-${_pkgver}/dist/bin/defaults/preferences ${pkgdir}${ICECATDIR}/defaults

}

md5sums=('877c092bc8c204a339f88bf093b0585f'
         '1bb4a77a63891bd82b2e9fc7caecd4b6'
         'e81ad01dbc16ba28bf92ba4b7c309ca7'
         'd93fe402b87cd000a869e1fd6badc6c9'
         'bd5db57c23c72a02a489592644f18995'
         '5a1938673a367b20ecfa009a5eb767aa')