# $Id: PKGBUILD 51860 2011-07-17 15:05:31Z ibiru $
# Maintainer: Thomas Baechler <thomas@archlinux.org>
# Contributor: James Rayner <iphitus@gmail.com>

_pkgbasename=nvidia-utils-beta
pkgname=lib32-$_pkgbasename
pkgver=285.03
pkgrel=2
pkgdesc="NVIDIA beta drivers utilities and libraries. (32-bit)"
arch=('x86_64')
url="http://www.nvidia.com/"
depends=('lib32-libxvmc' 'lib32-zlib' 'lib32-gcc-libs' $_pkgbasename)
conflicts=('lib32-libgl')
provides=('lib32-libgl=7.10.3')
license=('custom')
options=('!strip')

_arch='x86'
_pkg="NVIDIA-Linux-${_arch}-${pkgver}"
source=("http://us.download.nvidia.com/XFree86/Linux-x86/${pkgver}/NVIDIA-Linux-x86-${pkgver}.run")
md5sums=('8a0954af050083aa7756880f65cf3272')

build() {
    cd $srcdir
    sh ${_pkg}.run --extract-only
}

package() {
    cd $srcdir/${_pkg}

    # OpenGL library
    install -D -m755 libGL.so.$pkgver $pkgdir/usr/lib32/libGL.so.$pkgver
    # OpenGL core library
    install -D -m755 libnvidia-glcore.so.$pkgver $pkgdir/usr/lib32/libnvidia-glcore.so.$pkgver
    # XvMC
    install -D -m644 libXvMCNVIDIA.a $pkgdir/usr/lib32/libXvMCNVIDIA.a
    install -D -m755 libXvMCNVIDIA.so.$pkgver $pkgdir/usr/lib32/libXvMCNVIDIA.so.$pkgver
    # VDPAU
    install -D -m755 libvdpau_nvidia.so.$pkgver $pkgdir/usr/lib32/vdpau/libvdpau_nvidia.so.$pkgver
    # CUDA
    install -D -m755 libcuda.so.$pkgver $pkgdir/usr/lib32/libcuda.so.$pkgver
    install -D -m755 libnvcuvid.so.$pkgver $pkgdir/usr/lib32/libnvcuvid.so.$pkgver
    # nvidia-tls library
    install -D -m755 tls/libnvidia-tls.so.$pkgver $pkgdir/usr/lib32/libnvidia-tls.so.$pkgver
    # OpenCL
    install -D -m755 libnvidia-compiler.so.$pkgver $pkgdir/usr/lib32/libnvidia-compiler.so.$pkgver
    install -D -m755 libOpenCL.so.1.0.0 $pkgdir/usr/lib32/libOpenCL.so.1.0.0

    install -D -m755 libnvidia-cfg.so.$pkgver $pkgdir/usr/lib32/libnvidia-cfg.so.$pkgver
    install -D -m755 libnvidia-ml.so.$pkgver $pkgdir/usr/lib32/libnvidia-ml.so.$pkgver

    # create soname links
    for _lib in $(find $pkgdir -name '*.so*'); do
        _soname="$(dirname ${_lib})/$(readelf -d "$_lib" | sed -nr 's/.*Library soname: \[(.*)\].*/\1/p')"
        if [ ! -e "${_soname}" ]; then
            ln -s "$(basename ${_lib})" "${_soname}"
            ln -s "$(basename ${_soname})" "${_soname/.[0-9]*/}"
        fi
    done

    rm -rf "${pkgdir}"/usr/{include,share,bin}
    mkdir -p "$pkgdir/usr/share/licenses"
    ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}