# Maintainer: Kyle Keen <keenerd@gmail.com>
# Maintainer: lks <lukas dot graetz at web dot de>

pkgbase=xombrero
pkgname=('xombrero' 'xombrero3')
pkgver=1.6.3
pkgrel=1
pkgdesc="A minimalists web browser, vi-like while maintaining traditional web browser behavior."
arch=(armv7h 'i686' 'x86_64')
url="https://opensource.conformal.com/wiki/xombrero"
_watch="https://opensource.conformal.com/snapshots/xombrero/"
license=('custom:ISC')
makedepends=('libbsd' 'desktop-file-utils')
install=$pkgname.install
options=('!emptydirs')
source=(http://opensource.conformal.com/snapshots/$pkgname/$pkgname-$pkgver.tgz \
        LICENSE
        xombrero3.desktop)
md5sums=('11248a0f40542265022e8dfe692644da'
         'f3eeb6e8b70a3dcccb8ee57daf584c9e'
         '72f97fb1b7c255340381c0e640b7a8a1')

build() {
    cd "$srcdir/$pkgbase-$pkgver"
    export GTK_CFLAGS="${GTK_CFLAGS} -I/usr/include/gtk-2.0/"
    # no spam
    sed -i 's|https://www.cyphertite.com|https://archlinux.org|' xombrero.{c,conf,h}
    # relocations
    sed -i 's|/etc/ssl/cert.pem|/etc/ssl/certs/ca-certificates.crt|' xombrero.conf
    #sed -i 's|/usr/local/share/xombrero/style.css|/usr/share/xombrero/style.css|' xombrero.conf
    sed -i 's|/usr/local/share/|/usr/share/|' {unix.c,xombrero.conf,xombrero.h}
}


# That stuff seems to not be supported by makepkg (see package_)
_build_xombrero() {
    cd "${srcdir}"
    mkdir -p build-gtk2
    # Create hardlinks to save memory
    cp --no-clobber -R -l "$pkgbase-$pkgver" build-gtk2

    pushd "build-gtk2/$pkgbase-$pkgver"
    make PREFIX="/usr" -C linux GTK_VERSION=gtk2
    popd
}

_build_xombrero3() {
    cd "${srcdir}"
    mkdir -p build-gtk3
    cp --no-clobber -R -l "$pkgbase-$pkgver" build-gtk3

    pushd "build-gtk3/$pkgbase-$pkgver"

    cp ${srcdir}/$pkgbase-$pkgver/xombrero.h xombrero.h
    sed -i 's|/usr/share/xombrero|/usr/share/xombrero3|' xombrero.h

    make PREFIX="/usr" -C linux GTK_VERSION=gtk3
    popd
}

package_xombrero() {
    depends=('webkitgtk2' 'libbsd' 'desktop-file-utils')
    provides=('xxxterm')
    replaces=('xxxterm')

    _build_xombrero

    cd "$srcdir/build-gtk2/$pkgbase-$pkgver"
    mkdir -p "$pkgdir/usr/share/applications/"  # buggy makefile
    make PREFIX="/usr" DESTDIR="$pkgdir" install -C linux GTK_VERSION=gtk2
    install -Dm644 xombrero.conf     "$pkgdir/etc/skel/.xombrero.conf"
    install -Dm644 xombrero.desktop  "$pkgdir/usr/share/applications/xombrero.desktop"
    install -Dm755 config-checker.pl "$pkgdir/usr/bin/config-checker.pl"
    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_xombrero3() {
    depends=('webkitgtk3' 'libbsd' 'desktop-file-utils')
    provides=('xxxterm' 'xombrero')
    replaces=('xxxterm')

    _build_xombrero3

    cd "$srcdir/build-gtk3/$pkgbase-$pkgver"
    mkdir -p "$pkgdir/usr/share/applications/"  # buggy makefile
    make PREFIX="/usr" DESTDIR="$pkgdir" install -C linux GTK_VERSION=gtk3
    mv $pkgdir/usr/bin/xombrero $pkgdir/usr/bin/xombrero3
    mv $pkgdir/usr/share/man/man1/xombrero.1 $pkgdir/usr/share/man/man1/xombrero3.1
    mv $pkgdir/usr/share/xombrero $pkgdir/usr/share/xombrero3

    rm ${pkgdir}/usr/share/applications/xombrero.desktop
    install -Dm644 "$srcdir/xombrero3.desktop"  "$pkgdir/usr/share/applications/xombrero3.desktop"
    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}