# Maintainer: Dassault Systemes <CrashReports@DraftSight.com>
# Maintainer: dongfengweixiao  <dongfengweixiao "at" gmail {dot} com>
# Contributor: dongfengweixiao  <dongfengweixiao "at" gmail {dot} com>

pkgname=dassault-systemes-draftsight
pkgver=2012.1.1177
pkgrel=1
pkgdesc="With DraftSight, you can easily create professional CAD drawings. Supported file formats are DWT, DXF and DWG."
arch=('i686' 'x86_64')
url="http://www.draftsight.com/download-linux-ubuntu"
source=('http://www.draftsight.com/download-linux-ubuntu/draftSight.deb'
	'dassault-systemes_draftsight.desktop'
	'ft-rockey.rules')
license=('Commercial')
conflicts=('draftsight')
install=draftsight.install

_pkgprefix=opt/dassault-systemes/draftsight

depends=(
    fontconfig
    gcc-libs
    glib2
    glibc
    libcups
    libgl
    libice
    libsm
    libx11
    libxext
    libxrender
    libxt
    mesa
    nas
    util-linux
    zlib
)
md5sums=('6f737dfae32949e10b9eac873e24e1e8'
         '3a5cf440c860958d1beaddf45015fac8'
         'b2e84ed22e10237cdba880c914689937')
         
# Build and replace dependency list for x86_64
if [[ "$CARCH" == 'x86_64' ]]; then
    for i in ${depends[@]}
    do
        _depends_64+=("lib32-$i")
    done
    depends=("${_depends_64[@]}")
fi

package() {
    msg "Extracting the draftsight package"
    ar -xv draftSight.deb
    tar -xzvf data.tar.gz
    tar -xzvf control.tar.gz
    msg2 "Done extracting!"

    msg "Preparing install"
    install -d "$pkgdir"/{opt,var,usr/share/applications}
    mv -v opt/dassault-systemes "$pkgdir"/opt
    mv -v var/opt "$pkgdir"/var
    mv -v license* "$pkgdir"/var/opt/dassault-systemes/draftsight/licence
    msg2 "Done preparing!"

    msg "Actual installation"
    mkdir -p "${pkgdir}"/etc/profile.d
    echo "export PATH=\$PATH:/${_pkgprefix}/bin" > $pkgdir/etc/profile.d/$pkgname.sh
    chmod 644 "${pkgdir}"/etc/profile.d/$pkgname.sh
    install -D -m644 "${srcdir}"/ft-rockey.rules "${pkgdir}"/etc/udev/rules.d/ft-rockey.rules
    rm -rf "${pkgdir}"/opt/dassault-systemes/draftsight/mime/dassault-systemes_draftsight.desktop
    mv -v "${srcdir}"/dassault-systemes_draftsight.desktop "${pkgdir}"/opt/dassault-systemes/draftsight/mime/dassault-systemes_draftsight.desktop
    cp "${pkgdir}"/opt/dassault-systemes/draftsight/mime/dassault-systemes_draftsight.desktop "${pkgdir}"/usr/share/applications/dassault-systemes_draftsight.desktop
    chmod 644 "${pkgdir}"/usr/share/applications/dassault-systemes_draftsight.desktop
    install -D "${pkgdir}"/opt/dassault-systemes/draftsight/Eula/english/eula.htm "${pkgdir}"/usr/share/licenses/draftsight/eula.htm
    msg2 "Installation finished!"
}