# Maintainer: Jkkyll Wu <adaptee at gmail [dot] com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>

pkgname=qbittorrent
pkgver=3.0.8
pkgrel=1
pkgdesc="A bittorrent client written in C++ / Qt4 using the good libtorrent library"
arch=('i686' 'x86_64')
url="http://www.qbittorrent.org/"
license=('GPL')
depends=('qt' 'libtorrent-rasterbar' 'boost-libs' 'xdg-utils' 'geoip')
makedepends=('boost' 'which')
optdepends=('python: needed for search')
install="qbittorrent.install"
source=("http://downloads.sourceforge.net/sourceforge/qbittorrent/${pkgname}-${pkgver}.tar.xz"
"http://geolite.maxmind.com/download/geoip/database/GeoLiteCountry/GeoIP.dat.gz"
)


build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  cp ${srcdir}/GeoIP.dat ${srcdir}/${pkgname}-${pkgver}/src/geoip/ 

  ./configure --prefix=/usr --with-geoip-database-embedded

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make INSTALL_ROOT=${pkgdir} install
}

md5sums=('9e2b2e4c2d027b80676e94360836aee7'
         '82e119ef9d92f5b5ac203c6307030762')