prontera,155,181,5	script	Sample	757,{
mes "Hello, ^F509DE"+strcharinfo(0)+"^000000";
mes "Do you want to broadcast something? Payment is^FAEB60 "+.item_quantity+" "+getitemname( .item_id )+"^000000.";
if( countitem( .item_id ) >= .item_quantity ){
	next;
	if( select( "YES","NO" ) == 1 ){
		mes "Enter messages.";
		mes "Blocked words will be auto filtered.";
		input .@message$;
		explode( .@message_array$,.@message$," " );
		.@message_array_size = getarraysize( .@message_array$ );
		for( .@i = 0; .@i < .@message_array_size; .@i++ )
			if( compare( .filter_word_check$,":"+.@message_array$[.@i]+":" ) )
				.@message_array$[.@i] = "***";
		mes "Select a Color";
		.@color = select( .color_name_menu$ ) - 1;
		delitem .item_id,.item_quantity;
		announce "[ "+strcharinfo(0)+" ]:"+implode( .@message_array$," " ),0,"0x"+.color_code$[.@color];
	}
}
close;

OnInit:
// required item
.item_id = 671;
.item_quantity = 1;

// Colour Name List
setarray .color_name$,"RED","BLUE";
setarray .color_code$,"FF0000","0055FF";
.color_name_menu$ = implode( .color_name$,":" );

// Filter Words
setarray .filter_word$,"fuck","you";
.filter_word_check$ = ":"+implode( .filter_word$,":" )+":";
end;
}