prontera,155,181,5	script	Sample	757,{
do{
	mes "Weekly Monster : ";
	mes "Monster : ^0055FF"+.Monster[1]+" x "+getmonsterinfo( .Monster[0],0 )+"^000000";
	if( getarraysize( .Item ) ) 
		mes "Items : ^0055FF"+.Item[1]+" x "+getitemname( .Item[0] )+"^000000";
	if( getgmlevel() >= .GMLevel ){
		next;
		set .@i,select( "Change Monster","Edit Prize" );
		mes "Input ^0055FF"+( ( .@i == 1 )?"Monster":"Item" )+" ID^000000 :";
		do{
			input .@Input1,(( .@i == 1 )? 1001:501 ),(( .@i == 1 )? 2380:32767 );
		}while( (( .@i == 1 )? getmonsterinfo( .@Input1,0 ):getitemname( .@Input1 ) ) == "null" );
		mes "Input ^0055FF"+( (.@i == 1)?"Monster":"Item" )+" Amount^000000 :";
		input .@Input2,1,32767;
		mes ( ( .@i == 1 )?"Monster":"Item" )+" : "+.@Input2+" x ^0055FF"+( ( .@i == 1 )? getmonsterinfo( .@Input1,0 ):getitemname( .@Input1 ) )+"^000000";
		if( select("Confirm:Nope") == 1 ){
			if( .@i == 1 )
				setarray .Monster[0],.@Input1,.@Input2;
			else
				setarray .Item[0],.@Input1,.@Input2;
			mes "DONE";
		}
		next;
	}
}while( getgmlevel() >= .GMLevel );
close;

OnNPCKillEvent:
if( #MOBID != .Monster[0] ){
	set #MOBID,.Monster[0];
	set #AMOUNT,0;
}
if( killedrid == .Monster[0] ){
	set #AMOUNT,#AMOUNT + 1;
	dispbottom "Killed "+#AMOUNT+" / "+.Monster[1]+"  "+getmonsterinfo( .Monster[0],0 );
	if( #AMOUNT >= .Monster[1] ){
		dispbottom "Mission Accomplished";
		set #AMOUNT,0;
		if( getarraysize( .Item ) ) getitem .Item[0],.Item[1];
	}
}
end;

OnInit:
OnSun0001:
do{
	setarray .Monster[0],rand(1001,2380),100;
}while( getmonsterinfo( .Monster[0],0 ) == "null" );
set .GMLevel,60;
end;

}