# Maintainer: Chaniyth <chaniyth at yahoo dot com>
# Contributor: SpepS <dreamspepser at yahoo dot it>

_pkgbasename=gstreamer0.10
pkgname=lib32-$_pkgbasename
pkgver=0.10.31
pkgrel=1
pkgdesc="GStreamer Multimedia Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=("$_pkgbasename" 'lib32-libxml2>=2.7.7' 'lib32-glib2>=2.24.1')
makedepends=('intltool' 'pkgconfig' 'gcc-multilib' 'gtk-doc' 'gobject-introspection')
options=('!libtool')
source=("$url/src/gstreamer/gstreamer-$pkgver.tar.bz2")
sha256sums=('7f737e6d047c1ebeb4e1e0725fc377c5d9f12ee89186de7960be3cbba709ab84')

build() {

  export CC='gcc -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

  cd "$srcdir/gstreamer-$pkgver"

  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --libdir=/usr/lib32 --libexecdir=/usr/lib32 \
    --with-package-name="GStreamer (Archlinux)" \
    --with-package-origin="http://www.archlinux.org/"

  make
}

package() {

  cd "$srcdir/gstreamer-$pkgver"

  make DESTDIR="$pkgdir/" install

  #Remove unneded files
  rm -rf "$pkgdir"/usr/{bin,include,share}
}