# Maintainer: Christoph Wiechert <wio@psitrax.de>
# Contributor: Aliaksandr Stelmachonak <mail(at)ava1ar(dot)info>

pkgname=sflphone-kde
pkgver=1.2.3
pkgrel=2
pkgdesc="SIP/IAX2 softphone"
url="http://www.sflphone.org"
arch=('x86_64' 'i686')
license=('GPL3')
depends=('kdelibs' 'libpulse' 'libzrtpcpp' 'libyaml' 'dbus-c++' 'speex' 'libsamplerate' 'kdepimlibs')
makedepends=('autoconf' 'cmake' 'boost' 'automoc4')
options=(!makeflags)
conflicts=('sflphone')
source=(https://projects.savoirfairelinux.com/attachments/download/6423/sflphone-${pkgver}.tar.gz
	http://download.kde.org/stable/sflphone/1.2.3/src/sflphone-client-kde-${pkgver}.tar.xz)
md5sums=('774eb07bbfc0717ad1e0090623e34616' 'df7b6e4e8cd65cf5e48406f3e3ff32d7')

build() {
  # PJSIP
  cd "${srcdir}/sflphone-${pkgver}/daemon/libs/pjproject-2.0.1"
  ./configure
  make dep
  make

  # Daemon
  cd "${srcdir}/sflphone-${pkgver}/daemon"
  ./autogen.sh
  ./configure --prefix="/usr" --disable-ilbc
   make
   
  # KDE client
  cd "${srcdir}/sflphone-client-kde-${pkgver}"
  ./config.sh --prefix="/usr"
  cd build
  make 
}

package() {
  # daemon
  cd "${srcdir}/sflphone-${pkgver}/daemon"
  make DESTDIR="${pkgdir}" install
  
  # KDE client
  cd "${srcdir}/sflphone-client-kde-${pkgver}/build"
  make DESTDIR="${pkgdir}" install
}