# Maintainer: (epsilom) Xavier Corredor <xavier.corredor.llano (at) gmail.com>

pkgname=rekonq-git
_realname=rekonq
pkgver=20101211
pkgrel=1
pkgdesc="A WebKit based web browser for KDE"
arch=('i686' 'x86_64')
url="http://rekonq.kde.org"
license=('GPL')
depends=('kdebase-keditbookmarks')
makedepends=('automoc4' 'cmake' 'docbook-xsl' 'git')
provides=(${_realname})
conflicts=(${_realname})
install=${pkgname}.install
source=('patch')
md5sums=('86515d857298456cb34d60588ae2311c')

_gitroot="git://git.kde.org/${_realname}.git"
_gitname=${_realname}
 
build() {
  cd ${srcdir}

  msg "Connecting to GIT server...."

  if [ -d ${_gitname} ]; then
    cd ${_gitname} && git pull origin
    msg "The local files are updated."
  else
    git clone ${_gitroot}
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting make..."

  rm -rf ${srcdir}/build
  git clone ${srcdir}/${_gitname} ${srcdir}/build
  cd ${srcdir}/build
 
  # patch and run localization files
  patch -Np1 -i ${srcdir}/patch

  export RK_SRCS="${srcdir}/build"
  cd scripts
  chmod +x download_i18n.sh
  ./download_i18n.sh
  cd ..

  cmake . -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd ${srcdir}/build
  make DESTDIR=${pkgdir} install
}