prontera,155,181,5	script	OnlinePoint	757,{
mes "Exchange Point : "+#online_points;
mes "Pick an item";
set .@i,select( .item_menu$ ) - 1;
if( #online_points >= .point[.@i] ){
	set #online_points,#online_points - .point[.@i];
	getitem .item[.@i],.amount[.@i];
	mes "Done. Left "+#online_points+" point.";
}
else{
	mes "You need "+.point[.@i]+" point.";
}
close;

OnInit:
	// which map 
	set .map$,"prontera";
	// give how many point
	set .reward_point,1;
	// check every X seconds
	set .check_second,60;
	
	// item + amount + price list
	setarray .item,607,512,501;
	setarray .amount,1,2,3;
	setarray .point,10,20,30;

	set .@size,getarraysize( .item );
	for( set .@i,0; .@i < .@size; set .@i,.@i + 1 )
		set .item_menu$,.item_menu$ + .amount[.@i]+"x "+getitemname( .item[.@i] ) +" - "+.point[.@i]+" P" + ":";
	setmapflag .map$,mf_loadevent;
	set .npc_name$,strnpcinfo(0);
	end;

OnCheck:
	if( strcharinfo(3) == .map$ ){
		if( !checkvending() && !checkchatting() ){
			set #online_points,#online_points + .reward_point;
			dispbottom "Gained "+.reward_point+" point. Total : "+#online_points;
		}
	}
OnPCLoginEvent:
	addtimer ( .check_second * 1000 ),.npc_name$+"::OnCheck";
	end;
}