# $Id$
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer: Mladen Pejaković <pejakm@gmail.com>

pkgbase=gstreamer0.10-good-slim
pkgname=('gstreamer0.10-good-slim' 'gstreamer0.10-good-plugins-slim')
pkgver=0.10.30
pkgrel=1
arch=('i686' 'x86_64')
license=('LGPL')
makedepends=('intltool' 'pkgconfig' 'gstreamer0.10-base>=0.10.34' 'libshout' 'libdv' 'flac' 'wavpack' 'taglib' 'v4l-utils' 'bzip2' 'libpulse' 'jack' 'udev')
url="http://gstreamer.freedesktop.org/"
options=(!libtool !emptydirs)
source=(${url}/src/gst-plugins-good/gst-plugins-good-${pkgver}.tar.bz2)
sha256sums=('b12cba90b27d8423cd0a808939098d19db3996cfb9bf528507c6321782e095f6')

build() {
  cd "${srcdir}/gst-plugins-good-${pkgver}"
  sed -i '/AC_PATH_XTRA/d' configure.ac
  autoreconf
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --disable-static --enable-experimental \
    --disable-schemas-install \
    --disable-hal \
    --disable-esd \
    --disable-aalib --disable-libcaca --disable-gconf --disable-dv1394 \
    --disable-oss --disable-osx_audio --disable-osx_video \
    --disable-directsound --disable-gdk_pixbuf \
    --with-package-name="GStreamer Good Plugins Slim (Archlinux)" \
    --with-package-origin="http://www.archlinux.org/"

  make
  sed -e 's/gst sys ext/gst/' -i Makefile
}

package_gstreamer0.10-good-slim() {
  depends=('gstreamer0.10-base>=0.10.34' 'bzip2')
  pkgdesc="GStreamer Multimedia Framework Good plugin libraries with reduced and no GNOME dependecies"
  provides=("gstreamer0.10-good=${pkgver}")
  replaces=('gstreamer0.10-good')
  conflicts=('gstreamer0.10-good')

  cd "${srcdir}/gst-plugins-good-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}/etc/gconf"
}

package_gstreamer0.10-good-plugins-slim() {
  depends=("gstreamer0.10-good-slim=${pkgver}" 'libshout' 'libdv' 'flac' 'wavpack' 'taglib' 'v4l-utils' 'libpng' 'libjpeg' 'jack' 'libpulse' 'udev')
  pkgdesc="GStreamer Multimedia Framework Good Plugins (gst-plugins-good) with reduced and no GNOME dependecies"
  groups=('gstreamer0.10-plugins')
  provides=("gstreamer0.10-good-plugins=${pkgver}")
  replaces=('gstreamer0.10-wavpack' 'gstreamer0.10-shout2' 'gstreamer0.10-taglib' 'gstreamer0.10-libpng' 'gstreamer0.10-jpeg' 'gstreamer0.10-cairo' 'gstreamer0.10-flac' 'gstreamer0.10-speex' 'gstreamer0.10-annodex' 'gstreamer0.10-cdio' 'gstreamer0.10-dv' 'gstreamer0.10-pulse' 'gstreamer0-10-good-plugins')
  conflicts=('gstreamer0.10-wavpack' 'gstreamer0.10-shout2' 'gstreamer0.10-taglib' 'gstreamer0.10-libpng' 'gstreamer0.10-jpeg' 'gstreamer0.10-cairo' 'gstreamer0.10-flac' 'gstreamer0.10-speex' 'gstreamer0.10-annodex' 'gstreamer0.10-cdio' 'gstreamer0.10-dv' 'gstreamer0.10-bad-plugins<0.10.7' 'gstreamer0.10-pulse' 'gstreamer0-10-good-plugins')

  cd "${srcdir}/gst-plugins-good-${pkgver}"
  make -C sys DESTDIR="${pkgdir}" install
  make -C ext DESTDIR="${pkgdir}" install

}