pkgname=eclipse-platform
pkgver=4.2
pkgrel=1
_date=201206081400
pkgdesc="Eclipse Platform without plug-ins and SDK (a minimal installation suitable for complete per-user customization with the built-in Eclipse package manager)"
url="http://eclipse.org"
arch=('i686' 'x86_64')
license=('EPL')
depends=('gtk2' 'hicolor-icon-theme')
optdepends=('libwebkit: Internal browser component and tooltips' 'libjpeg6-turbo: JPEG supporting library' 'libpng12: PNG supporting library')
conflicts=('eclipse')
provides=("eclipse=$pkgver")
install=eclipse-platform.install

source=(
    "ftp://ftp.osuosl.org/pub/eclipse/eclipse/downloads/drops4/R-${pkgver}-${_date}/eclipse-platform-${pkgver}-linux-gtk.tar.gz"
    "eclipse.sh"
    "eclipse.svg"
    "eclipse.desktop"
)

md5sums=(
    'f7d942a0f758ba68be73899baee2c74c'
    '8dbd219db72d2c913f2e086f19a65770'
    'f083188c833ba05a3ce8c6b16a290c12'
    '73c5c6ad00c72888080ff3cde413942f'
)

if [ "$CARCH" = "x86_64" ]; then
    source[0]="ftp://ftp.osuosl.org/pub/eclipse/eclipse/downloads/drops4/R-${pkgver}-${_date}/eclipse-platform-${pkgver}-linux-gtk-$CARCH.tar.gz"
    md5sums[0]='0e4a33e4cfba9c5282a43736d33b7d56'
fi

package() {
    # install eclipse
    install -m755 -d "$pkgdir/usr/share"
    cp -r "${srcdir}/eclipse" "$pkgdir/usr/share/"
    
    # install misc
    install -m755 -d ${pkgdir}/usr/bin ${pkgdir}/usr/share/applications ${pkgdir}/usr/share/icons/hicolor/{16x16,32x32,48x48,256x256,scalable}/apps
    
    install -m755 "${srcdir}/eclipse.sh" "${pkgdir}/usr/bin/eclipse"
    install -m644 "${srcdir}/eclipse.desktop" "${pkgdir}/usr/share/applications/"
    
    # install icons
    install -m644 "${srcdir}/eclipse/plugins/org.eclipse.platform_${pkgver}.0.v${_date}/eclipse16.png" "${pkgdir}/usr/share/icons/hicolor/16x16/apps/eclipse.png"
    install -m644 "${srcdir}/eclipse/plugins/org.eclipse.platform_${pkgver}.0.v${_date}/eclipse32.png" "${pkgdir}/usr/share/icons/hicolor/32x32/apps/eclipse.png"
    install -m644 "${srcdir}/eclipse/plugins/org.eclipse.platform_${pkgver}.0.v${_date}/eclipse48.png" "${pkgdir}/usr/share/icons/hicolor/48x48/apps/eclipse.png"
    install -m644 "${srcdir}/eclipse/plugins/org.eclipse.platform_${pkgver}.0.v${_date}/eclipse256.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/eclipse.png"
    
    install -m644 ${srcdir}/eclipse.svg ${pkgdir}/usr/share/icons/hicolor/scalable/apps/eclipse.svg
}