# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Maintainer: TheBenj88 <thebenj88 *AT* gmail *DOT* com>

pkgname=openxcom
pkgver=0.9
pkgrel=2
pkgdesc="An open-source reimplementation of the famous X-COM game"
arch=('i686' 'x86_64')
url="http://openxcom.org/"
license=('GPL3')
depends=('sdl' 'gcc-libs' 'sdl_gfx' 'sdl_mixer' 'sdl_image' 'timidity++' 'yaml-cpp0.3' 'mesa' 'glu')
install="${pkgname}.install"
source=("https://github.com/SupSuper/OpenXcom/tarball/v${pkgver}"
		"${pkgname}.install"
		"${pkgname}.png"
		"${pkgname}.desktop")
sha256sums=('340ff7292baa9a2b7ce4b244cc6dc0200c1d3b807a59087ef9827bba5c135634'
            '102150a0124ffe1fe1ab11f05d2e7a8c8e20decba9cef78fa831fc2429cc8e46'
	    '4b46d69031f223beaa3bfe90f327652a2b3c4db07fa7bfe40cc44436c22d2c52'
	    'a12a22370a0246d7670a6117b6b7523b68eb74236e8de81503ac8d0b7bed64f0')

build() {
  cd "${srcdir}/SupSuper-OpenXcom-5c8b540/src"
  mv Makefile.simple Makefile
  # Fix a problem with yaml-cpp and pkg-config
  sed -i "s_--cflags sdl yaml-cpp\`_--cflags sdl\` -I/usr/include/yaml-cpp_" Makefile
  # Fix a compilation error
  sed -i "s_?=_+=_" Makefile

  make || return 1
}

package() {
  cd "${srcdir}/SupSuper-OpenXcom-5c8b540"

  # Install binary
  install -Dm755 "bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"

  # Install data files
  mkdir -p "${pkgdir}/usr/share/${pkgname}/data/"{Language,SoldierName,Shaders,Ruleset}
  install -m644 bin/data/Language/* "${pkgdir}/usr/share/${pkgname}/data/Language"
  install -m644 bin/data/SoldierName/* "${pkgdir}/usr/share/${pkgname}/data/SoldierName"
  install -m644 bin/data/Shaders/* "${pkgdir}/usr/share/${pkgname}/data/Shaders"
  install -m644 bin/data/Ruleset/* "${pkgdir}/usr/share/${pkgname}/data/Ruleset"

  # Install Desktop Files
  install -Dm755 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm644 "${srcdir}/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png" 

  # Install readme
  install -Dm644 README.txt "${pkgdir}/usr/share/doc/${pkgname}/README"
}