# Maintainer: Wyatt J. Brown <sushidudeteam@gmail.com>
pkgname=eclipse-pydev
pkgver=3.9.1
pkgrel=1
pkgdesc='A Python IDE for Eclipse.'
arch=('any')
url='http://pydev.org/'
license=('EPL')
depends=('eclipse')
source=("http://downloads.sourceforge.net/project/pydev/pydev/PyDev%20$pkgver/PyDev%20$pkgver.zip")
sha512sums=('b148e1d9658001a24509097c4dc0ca4503e050582b64b7d2ff41cee5d4eed7da8c18a36402c6cbe68287ff75f1bc4b758afa3e77c04327e8017200af9af98183')

package()
{
	_dest=${pkgdir}/usr/share/eclipse/dropins/${pkgname/eclipse-}/eclipse

	# Features
	find features -type f | while read _feature ; do
		if [[ ${_feature} =~ (.*\.jar$) ]] ; then
			install -dm755 ${_dest}/${_feature%*.jar}
			cd ${_dest}/${_feature/.jar}
			# extract features (otherwise they are not visible in about dialog)
			jar xf ${srcdir}/${_feature} || return 1
		else
			install -Dm644 ${_feature} ${_dest}/${_feature}
		fi
	done

	# Plugins
	find plugins -type f | while read _plugin ; do
		install -Dm644 "${_plugin}" "${_dest}/${_plugin}"
	done
}