#	Date		-	Update Log Entry
#	12/12/2013	-	Updated /tpr to be more customizable
#	12/13/2013	-	Updated /tpr to fix a bug when checking for 0
#	12/16/2013	-	Updated /tpr to set player Pitch and Yaw
#	01/23/2014	-	Merged Vote Help with Vote Command, Tweaks to /tpr, Tweaks to /reload
#	01/24/2014	- 	Fixed Yesterday's date, Fixed missing / in /reload for STL, Tweaks to /vote

#give - Smites anyone that doesn't have permission for /give
*:/give $ = >>>
    if(has_permission(player(),'essentials.give'),
        # then
        run('/give' $)
    , # else
        msg(concat(color('red'), '[FCoFix] No permission for /give'))
        lightning(ploc(player()))
    )
<<<

#help - Replace Essentials Help to Prevent players from seeing plugins
*:/help [$search=''] [$=''] = >>>
    msg(concat(
        color('yellow'),
        ' ---- ',
        color('gold'),
        'List: commands',
        color('yellow'),
        ' -- ',
        color('gold'),
        'Page ',
        color('red'),
        '1',
        color('gold'),
        '/',
        color('red'),
        '1',
        color('yellow')
        '---- '
    ))
    msg(concat(
        color('gold'),
        '/Put, /Available, /Commands, /Here'
    ))
<<<

#plugins - Replace /Plugins to Prevent Players from seeing plugins
*:/plugins = >>>
    msg(concat(
        color('white'),
        'Plugins (3): ',
        color('green'),
        'FCoFixTekkitPack, TekkitHacksDetector, TekkitLockdown'
    ))
<<<

#reload - Reloads all available plugins
reload:/reload [$=''] = >>>
    run('/CapsBlock reload')
    run('/Essentials reload')
    run('/ReloadAliases')
    run('/STL reload')
    run('/TekkitRestrict admin reload')
    run('/WB reload')
    run('/WE reload')
    run('/WG reload')
<<<

#save - Short for /save-all
/save [$=''] = >>>
    run('/save-all')
<<<

#tpr - Random TP
*:/tpr = >>>
    assign(@min, 1024) # Replace 512 with your minimum distance
    assign(@max, 16384) # Replace 16384 with your maximum distance
    assign(@zero, 0005) # Replace 0005 with times to check for zero 
    assign(@spawnx, -192) # Replace -192 with the X coord of your spawn
    assign(@spawnz, -328) # Replace -328 with the Z coord of your spawn
    # Ensures X TP both - and +, but not 0
    assign(@r0,rand(-1,1))
    for(
        assign(@i,1), 
        lte(@i,@zero),
        inc(@i),
        if(equals(@r0,0),
            # then
            assign(@r0,rand(-1,1))
        )
    )
    # Ensures Z TP both - and +, but not 0
    assign(@r1,rand(-1,1))
    for(
        assign(@i,1), 
        lte(@i,@zero),
        inc(@i),
        if(equals(@r1,0),
            # then
            assign(@r1,rand(-1,1))
        )
    )
    # X
    assign(@X,
        add(
            @spawnx,
            multiply(
                @r0,
                rand(@min, @max)
            )
        )
    )
    # Y, Make sure the player is holding swiftwolf! It's a long fall!
    assign(@Y, 128)
    #Z
    assign(@Z,
        add(
            @spawnz,
            multiply(
                @r1,
                rand(@min, @max)
            )
        )
    )
    # Set player facing North, and Neither Up Nor Down
    pfacing(180,0)
    # Does the Actual TP of Player using /tpr
    set_ploc(player(), @X, @Y, @Z)
<<<

#tprandom - Random TP caller
*:/tprandom = >>>
    call_alias('/tpr')
<<<

#Vote - Used for voting sites
*:/vote [$site=null] = >>>
    assign(@site1, ' http://www.votesite1.com/yourserver') # Replace with a vote site
    assign(@site2, ' http://www.votesite2.com/yourserver') # Replace with a vote site
    assign(@site3, ' http://www.votesite3.com/yourserver') # Replace with a vote site
    switch(equals(1,1), # Case Statement
        is_null($site), # Case No Parameters
            msg(concat(
                color('yellow'),
                ' ---- ',
                color('gold'),
                'List: Vote',
                color('yellow'),
                ' -- ',
                color('gold'),
                'Page ',
                color('red'),
                '1',
                color('gold'),
                '/',
                color('red'),
                '1',
                color('yellow')
                '---- '
            ))
            msg(concat(color('gold'),'Site 1',color('white'),': ',@site1))
            msg(concat(color('gold'),'Site 2',color('white'),': ',@site2))
            msg(concat(color('gold'),'Site 3',color('white'),': ',@site3)),
        switch(equals(1,1), # Case Parameters
            equals($site,0), run('/vote'),
            equals($site,1), msg(concat(color('gold'),@site1)),
            equals($site,2), msg(concat(color('gold'),@site2)),
            equals($site,3), msg(concat(color('gold'),@site3)),
            call_alias('/vote')
        )
    )
<<<