# Maintainer: LEW21 <lew21@xtreeme.org>

pkgname=lib32-mesa-full
pkgver=9.2.0_devel.56992
_realver=9.2
pkgrel=1
pkgdesc="Full Mesa 3D graphics library with all its components, built from the git master branch. For Wayland/VDPAU support ask multilib maintainers for lib32-{wayland,libvdpau}. RadeonSI support disabled until LLVM 3.3 gets released."
arch=('x86_64')
url="http://mesa3d.org/"
license=('LGPL')
depends=('lib32-libdrm' 'lib32-libxxf86vm' 'lib32-libxdamage' 'lib32-systemd' 'lib32-llvm') # no lib32-libvdpau, no lib32-wayland ;(
makedepends=('git' 'python2' 'lib32-libxml2' 'lib32-libx11' 'glproto' 'dri2proto' 'lib32-libxvmc')
optdepends=('lib32-libtxc_dxtn: S3TC support'
'lib32-mesa-demos: glxinfo and glxgears'
'opengl-man-pages: for the OpenGL API man pages')

provides=("lib32-mesa=${_realver}" "lib32-mesa-libgl=${_realver}" "lib32-libgl" 'lib32-libglapi' 'lib32-osmesa' 'lib32-libgbm' 'lib32-libgles' 'lib32-libegl'
"lib32-ati-dri=${_realver}" "lib32-intel-dri=${_realver}" "lib32-nouveau-dri=${_realver}" "lib32-svga-dri=${_realver}")
conflicts=('lib32-mesa' 'lib32-mesa-libgl' 'lib32-libgl' 'lib32-libglapi' 'lib32-osmesa' 'lib32-libgbm' 'lib32-libgles' 'lib32-libegl' 'lib32-ati-dri' 'lib32-intel-dri' 'lib32-nouveau-dri' 'lib32-svga-dri')

source=(git://anongit.freedesktop.org/git/mesa/mesa)
sha1sums=('SKIP')

pkgver() {
	cd mesa
	echo $(grep --max-count=1 -F "AC_INIT([Mesa], [" configure.ac | cut -f2 -d " " | cut -f2 -d "[" | cut -f1 -d "]" | tr "-" "_").$(git rev-list --count HEAD)
}

build() {
	export CC="gcc -m32"
	export CXX="g++ -m32"
	export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
	export LLVM_CONFIG=/usr/bin/llvm-config32

	cd mesa

	export PYTHON=/usr/bin/python2

	./autogen.sh --enable-32-bit --libdir=/usr/lib32 --prefix=/usr \
		--sysconfdir=/etc \
		--with-dri-driverdir=/usr/lib32/xorg/modules/dri \
		--with-gallium-drivers=r300,r600,nouveau,svga,swrast \
		--with-dri-drivers=i915,i965,r200,radeon,nouveau \
		--disable-radeon-llvm \
		--enable-gallium-llvm \
		--enable-egl \
		--enable-gallium-egl \
		--with-egl-platforms=drm,x11 \
		--enable-shared-glapi \
		--enable-gbm \
		--enable-glx-tls \
		--enable-osmesa \
		--enable-gles1 \
		--enable-gles2 \
		--enable-texture-float \
		--disable-xa \
		--disable-vdpau \

	make
}

package() {
	cd mesa

	make DESTDIR="${pkgdir}" install

	rm -Rf "${pkgdir}/usr/include"
	rm -Rf "${pkgdir}/etc"
}