# Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>

pkgname=ubuntu-themes
_actual_ver=13.04
_extra_ver=daily13.05.31
pkgver=${_actual_ver}${_extra_ver}
pkgrel=100
pkgdesc="Ubuntu monochrome icon theme, Abmiance and Radiance themes, and Ubuntu artwork"
arch=('any')
url="https://launchpad.net/ubuntu-themes"
license=('CCPL')
groups=('unity-extra')
depends=('humanity-icon-theme' 'gnome-icon-theme' 'hicolor-icon-theme' 'gtk-engine-unico' 'gtk-engine-murrine')
makedepends=('python2' 'imagemagick' 'icon-naming-utils')
provides=('light-themes' 'ubuntu-mono')
conflicts=('light-themes' 'ubuntu-mono')
install=${pkgname}.install
source=("https://launchpad.net/ubuntu/+archive/primary/+files/${pkgname}_${_actual_ver}${_extra_ver}.orig.tar.gz")
sha512sums=('89d35688b3a54d9d2636fe49ff7863e8ef266842413808c29eaba4dd1513a8ff9fe0d03372e4d391fd178cb28966b0eef886603c0b0fa378bf41ff25f45dd03d')

build() {
  cd "${srcdir}/${pkgname}-${_actual_ver}${_extra_ver}"

  # Python 2 fix
  sed -i 's|^\(#!.*python$\)|\12|g' scavenge.py

  make
}

package() {
  cd "${srcdir}/${pkgname}-${_actual_ver}${_extra_ver}"

  # Install themes
  install -dm755   "${pkgdir}/usr/share/themes/"
  cp -av Ambiance/ "${pkgdir}/usr/share/themes/"
  cp -av Radiance/ "${pkgdir}/usr/share/themes/"

  # Install icons
  install -dm755            "${pkgdir}/usr/share/icons/"
  cp -av ubuntu-mono-dark/  "${pkgdir}/usr/share/icons/"
  cp -av ubuntu-mono-light/ "${pkgdir}/usr/share/icons/"
  cp -av LoginIcons/        "${pkgdir}/usr/share/icons/"

  install -Dm644 distributor-logo.png \
    "${pkgdir}/usr/share/icons/hicolor/48x48/apps/distributor-logo.png"
    
  sed -i -e "/shadow radius/d" "$pkgdir/usr/share/themes/Ambiance/metacity-1/metacity-theme-1.xml"
  sed -i -e "/shadow radius/d" "$pkgdir/usr/share/themes/Radiance/metacity-1/metacity-theme-1.xml"
  sed -i -e "/padding/d" "$pkgdir/usr/share/themes/Ambiance/metacity-1/metacity-theme-1.xml"
  sed -i -e "/padding/d" "$pkgdir/usr/share/themes/Radiance/metacity-1/metacity-theme-1.xml"

  sed -i -e "/trough/d" "$pkgdir/usr/share/themes/Ambiance/metacity-1/metacity-theme-1.xml"
  sed -i -e "/trough/d" "$pkgdir/usr/share/themes/Radiance/metacity-1/metacity-theme-1.xml"
}

# vim:set ts=2 sw=2 et: