# Maintainer: prettyvanilla <prettyvanilla@lavabit.com>
# Contributor: JKAbrams <JKAbrams@aur>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Charles Lindsay <charles@chaoslizard.org>

_pkgname=vhba-module
pkgname=vhba-module-ck
pkgver=20130607
_extramodules=extramodules-$(uname -r | cut -d. -f1-2)-ck
pkgrel=2
pkgdesc="Kernel module that emulates SCSI devices. For linux-ck."
arch=('i686' 'x86_64')
url="http://cdemu.sourceforge.net/"
license=('GPL')
depends=('linux-ck>=3.9' 'linux-ck<3.10')
makedepends=('linux-ck-headers')
provides=('vhba-module=20130607')
options=(!makeflags)
install=$pkgname.install
source=("http://downloads.sourceforge.net/cdemu/$_pkgname-$pkgver.tar.bz2"
        '60-vhba.rules')
md5sums=('92a681e4665aa85a8335d00395a61697'
         '4dc37dc348b5a2c83585829bde790dcc')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  _kernver="$(cat /usr/lib/modules/$_extramodules/version)"

  make KDIR=/usr/lib/modules/$_kernver/build
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  install -Dm644 vhba.ko "$pkgdir/usr/lib/modules/$_extramodules/vhba.ko"
  install -Dm644 ../60-vhba.rules "$pkgdir/usr/lib/udev/rules.d/60-vhba.rules"

  cd $startdir
  cp -f $install ${install}.pkg
  true && install=${install}.pkg
  sed -i "s/EXTRAMODULES=.*/EXTRAMODULES=$_extramodules/" $install
}