# Contributor : Giuseppe Calderaro <giuseppecalderaro@gmail.com>

pkgname=nvidia-ice
pkgver=260.19.21
_kernver='2.6.36-ice'
pkgrel=1
pkgdesc="NVIDIA drivers for kernel26-ice."
arch=('i686' 'x86_64')
url="http://www.nvidia.com/"
depends=("kernel26-ice" "nvidia-utils=${pkgver}")
conflicts=('nvidia-96xx-ice' 'nvidia-173xx-ice' 'nvidia-ice-beta')
license=('custom')
install=nvidia-ice.install

if [ "$CARCH" = "i686" ]; then
	_arch='x86'
	_pkg="NVIDIA-Linux-${_arch}-${pkgver}"
	source=("ftp://download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
	md5sums=('2ec917f51e752802646920e9bcd747e7')
elif [ "$CARCH" = "x86_64" ]; then
	_arch='x86_64'
	_pkg="NVIDIA-Linux-${_arch}-${pkgver}-no-compat32"
	source=("ftp://download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
	md5sums=('9db612fb5679249627d52bfff0e16f4f')	
fi

build() {
	cd $srcdir
	sh ${_pkg}.run --extract-only
	cd ${_pkg}/kernel
	make SYSSRC=/lib/modules/${_kernver}/build module || return 1
}

package() {
	install -D -m644 $srcdir/${_pkg}/kernel/nvidia.ko \
		$pkgdir/lib/modules/${_kernver}/kernel/drivers/video/nvidia.ko || return 1
	install -d -m755 $pkgdir/etc/modprobe.d
        echo "blacklist nouveau" >> $pkgdir/etc/modprobe.d/nouveau_blacklist.conf || return 1
	sed -i -e "s/KERNEL_VERSION='.*'/KERNEL_VERSION='${_kernver}'/" $startdir/nvidia-ice.install
}