# Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: joel schaerer <joel.schaerer@laposte.net>

pkgname=insight-toolkit
pkgver=4.7.2
pkgrel=1
pkgdesc='Insight Segmentation and Registration Toolkit (ITK).'
arch=('i686' 'x86_64')
url='http://www.itk.org/'
license=('APACHE')
depends=('fftw' 'libjpeg-turbo' 'libpng' 'zlib' 'libtiff' 'gdcm' 'expat' 'hdf5-cpp-fortran')
makedepends=('cmake')
source=("http://downloads.sourceforge.net/project/itk/itk/${pkgver:0:3}/InsightToolkit-${pkgver}.tar.xz"
        "patch.zip::http://review.source.kitware.com/changes/19724/revisions/7f54e86422092a01a7ce2c836b44d7e583c9b370/patch?zip")
sha512sums=('977928df3d28374de5a37a7f13d69540d4183c41c7a4112df7eb98c3328ab2b5e6774c5857241cd8b1b5c65c1762c2badb7b53391a74a15193aa344260749c20'
            'a728f97f896e9d61f18c0aab5f6e816422ea080a4e81cd5f93bd1d2f25b8fc549b9f5991a3f86d241a9bd24f176c513640717504fa554f4df7cbd813edefa75d')



prepare() {
  msg "Patching for GCC 5.1 compatibility"
  cd "$srcdir/InsightToolkit-${pkgver}"
  patch -Np1 -i "$srcdir/7f54e864.diff"
}

build() {
  cd "$srcdir"
  rm -rf build
  mkdir build
  cd build

  cmake \
    -DCMAKE_BUILD_TYPE:STRING=Release \
    -DBUILD_TESTING:BOOL=OFF \
    -DBUILD_EXAMPLES:BOOL=OFF \
    -DBUILD_SHARED_LIBS:BOOL=ON \
    -DCMAKE_INSTALL_PREFIX:FILEPATH=/usr \
    -DModule_ITKReview:BOOL=ON \
    -DITK_USE_SYSTEM_JPEG:BOOL=ON \
    -DITK_USE_SYSTEM_PNG:BOOL=ON \
    -DITK_USE_SYSTEM_ZLIB:BOOL=ON \
    -DITK_USE_SYSTEM_TIFF:BOOL=ON \
    -DITK_USE_SYSTEM_GDCM:BOOL=ON \
    -ITK_LEGACY_SILENT:BOOL=ON \
    -ITK_WRAP_PYTHON:BOOL=ON \
    -DITK_USE_SYSTEM_EXPAT:BOOL=ON \
    -DITK_USE_SYSTEM_FFTW:BOOL=ON \
    -DITK_USE_SYSTEM_HDF5:BOOL=ON \
    ../InsightToolkit-${pkgver}

  make
}

package() {
  cd "$srcdir"/build

  make DESTDIR="${pkgdir}" install
}