# Maintainer : Thomas Baechler <thomas@archlinux.org>
# non-maintainer edits: changed kernel version to build for -ck

pkgname=nvidia-ck
pkgver=256.53
_kernver='2.6.35-ck'
pkgrel=1
pkgdesc="NVIDIA drivers for kernel26-ck."
arch=('i686' 'x86_64')
url="http://www.nvidia.com/"
depends=('kernel26-ck>=2.6.35' 'kernel26-ck<2.6.36' "nvidia-utils=${pkgver}")
makedepends=('kernel26-ck-headers>=2.6.35' 'kernel26-ck-headers<2.6.36')
conflicts=('nvidia-96xx' 'nvidia-173xx')
license=('custom')
install=nvidia-ck.install

if [ "$CARCH" = "i686" ]; then
        _arch='x86'
        _pkg="NVIDIA-Linux-${_arch}-${pkgver}"
        source=("ftp://download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
        md5sums=('21fe3fe0afed7818b7adf383477b2155')
elif [ "$CARCH" = "x86_64" ]; then
        _arch='x86_64'
        _pkg="NVIDIA-Linux-${_arch}-${pkgver}-no-compat32"
        source=("ftp://download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
        md5sums=('73f08a19e00d05165cbbfc74e2fa4bdd')
fi

build() {
        cd $srcdir
        sh ${_pkg}.run --extract-only
        cd ${_pkg}/kernel
        make SYSSRC=/lib/modules/${_kernver}/build module
}

package() {
        install -D -m644 $srcdir/${_pkg}/kernel/nvidia.ko \
                $pkgdir/lib/modules/${_kernver}/kernel/drivers/video/nvidia.ko
#        install -d -m755 $pkgdir/etc/modprobe.d
#        echo "blacklist nouveau" >> $pkgdir/etc/modprobe.d/nouveau_blacklist.conf
#       sed -i -e "s/KERNEL_VERSION='.*'/KERNEL_VERSION='${_kernver}'/" $startdir/nvidia.install
}