# Maintainer: Hilinus

pkgname=aegisub-svn
pkgver=5819
pkgrel=1
pkgdesc="A general-purpose subtitle editor with ASS/SSA support"
arch=('i686' 'x86_64')
url="http://www.aegisub.net"
license=('GPL' 'BSD')
depends=('ffmpegsource2-svn' 'lua' 'wxgtk-2.9>=2.9.2' 'hunspell' 'libass' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('imagemagick>=6.6.2.10' 'subversion' 'intltool')
provides=('aegisub')
conflicts=('aegisub')
source=('license.txt')
options=(!strip)
install=aegisub-svn.install
md5sums=('3e13350007702bd7117e8f35bac376f1')

_svntrunk=http://svn.aegisub.org/trunk/aegisub/
_svnmod=aegisub


build() {
  cd "$srcdir"

  if [ -d $_svnmod ]; then
    cd $_svnmod && svn up
  else
    svn co $_svntrunk $_svnmod
  fi

  if [ -d "$srcdir/$_svnmod-build" ]; then
    rm -rf "$srcdir/$_svnmod-build"
  fi

  cp -r "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"

  cd "$srcdir/$_svnmod-build"

  ./autogen.sh --prefix=/usr \
    --with-player-audio=alsa --without-{portaudio,openal,oss,pulseaudio} \
		--with-wxdir=/usr/include/wx-2.9 --with-wx-config=/usr/bin/wx-config-2.9

  make
}

package() {
  cd "${srcdir}/$_svnmod-build"
  make DESTDIR="$pkgdir" install

  # menu icon and mimetype fix
  sed -i -e 's/Icon=aegisub/Icon=\/usr\/share\/icons\/hicolor\/scalable\/apps\/aegisub.svg/' \
  -e 's/application\/x-srt/application\/x-subrip/' \
  "$pkgdir"/usr/share/applications/aegisub.desktop

  # install the BSD license, although it is ruled by GPL according to the wiki:
  # (http://www.malakith.net/aegiwiki/Subtitling_software_comparison)
  install -D -m644 "$srcdir"/license.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/license.txt
}