# Maintainer: Victor Dmitriyev <mrvvitek@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Simon Lipp <sloonz+aur@gmail.com>
# Contributor: Eric Schisselbauer <eric.schisselbauer@gmail.com>

pkgname=jogl
pkgver=2.1.3
pkgrel=1
pkgdesc='OpenGL bindings for Java'
arch=('x86_64' 'i686')
url="http://jogamp.org/"
license=('BSD')
depends=('java-runtime' 'libgl')
source=("jogl.license.txt"
  "gluegen.license.txt"
        "http://jogamp.org/deployment/v${pkgver}/jar/orig/jogl-all.jar"
        "http://jogamp.org/deployment/v${pkgver}/jar/orig/gluegen-rt.jar")
md5sums=('4f7cc7c2a95c4d1e1d0670ed497c06b3'
         '88456d8059e998bff8868c2b4d0347ce'
         '9de708bbc12ce4d26de83deb1d6c641a'
         '5dae78d64502a07c78ada81d06b64778')

[[ "$CARCH" == "i686" ]] && {
source+=("http://jogamp.org/deployment/v${pkgver}/jar/orig/jogl-all-natives-linux-i586.jar"
        "http://jogamp.org/deployment/v${pkgver}/jar/orig/gluegen-rt-natives-linux-i586.jar")
md5sums+=('481d68d10d47bf080dcb175cf786139f'
        '682f9a9087026eb3ad1e8d63cd46a211')
}
[[ "$CARCH" == "x86_64" ]] && {
source+=("http://jogamp.org/deployment/v${pkgver}/jar/orig/jogl-all-natives-linux-amd64.jar"
        "http://jogamp.org/deployment/v${pkgver}/jar/orig/gluegen-rt-natives-linux-amd64.jar")
md5sums+=('655c0b6e0649f10090646d0bfaed9206'
        '1d6c606da17ce4e3d5b48bcca16cf286')
}
noextract=({jogl-all,gluegen-rt}.jar)

package() {
  cd "${srcdir}"
  install -Dm644 "jogl-all.jar" "${pkgdir}/usr/share/java/${pkgname}/jogl-all.jar"
  install -Dm644 "gluegen-rt.jar" "${pkgdir}/usr/share/java/${pkgname}/gluegen-rt.jar"
  install -Dm644 "libgluegen-rt.so" "${pkgdir}/usr/lib/${pkgname}/libgluegen-rt.so"
  install -Dm644 "libjogl_desktop.so" "${pkgdir}/usr/lib/${pkgname}/libjogl_desktop.so"
  install -Dm644 "libjogl_mobile.so" "${pkgdir}/usr/lib/${pkgname}/libjogl_mobile.so"
  install -Dm644 "libnativewindow_awt.so" "${pkgdir}/usr/lib/${pkgname}/libnativewindow_awt.so"
  install -Dm644 "libnativewindow_x11.so" "${pkgdir}/usr/lib/${pkgname}/libnativewindow_x11.so"
  install -Dm644 "libnewt.so" "${pkgdir}/usr/lib/${pkgname}/libnewt.so"
  install -Dm644 "jogl.license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/jogl.license.txt"
  install -Dm644 "gluegen.license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/gluegen.license.txt"

  cd "${pkgdir}/usr/share/java/${pkgname}"
  ln -s "jogl-all.jar" "jogl2.jar"
  ln -s "gluegen-rt.jar" "gluegen2-rt.jar"
  cd "${pkgdir}/usr/lib"
  ln -s "jogl" "jogl2"
  ln -s "jogl" "gluegen2"
  ln -s "libgluegen-rt.so" "jogl/libgluegen2-rt.so"
}

# vim:set ts=2 sw=2 et: