# Maintainer: Mikael Eriksson <mikael_eriksson@miffe.org>
# Contributor: Andreas Krinke <andreas krinke gmx de>

pkgname=mingw32-libpng
pkgver=1.4.3
pkgrel=1
arch=('any')
pkgdesc="A collection of routines used to create PNG format graphics (mingw32)"
depends=('mingw32-runtime' 'mingw32-zlib')
makedepends=('mingw32-gcc')
license=('LGPL')
url="http://www.libpng.org/pub/png/libpng.html"
source=("http://downloads.sourceforge.net/sourceforge/libpng/libpng-$pkgver.tar.bz2"
        "http://downloads.sourceforge.net/project/libpng-apng/libpng-master/$pkgver/libpng-$pkgver-apng.patch.gz"
        win32.cmake)
md5sums=('9347eeda4241401f7da4dc9ba7f6a416'
         'faa3daaeafc0709c267374ca90cd8482'
         'f6be7e20150164e8bd342e571d37db51')

build() {
  cd "${srcdir}/libpng-${pkgver}"
  cp "${srcdir}/win32.cmake" .

  unset LDFLAGS # mingw-ld chokes on --hash-style=gnu

  # Add animated PNG (apng) support
  # see http://sourceforge.net/projects/libpng-apng/
  patch -p1 -i "${srcdir}/libpng-${pkgver}-apng.patch" || return 1

  cmake . \
    -DCMAKE_TOOLCHAIN_FILE=win32.cmake \
    -DCMAKE_INSTALL_PREFIX=/usr/i486-mingw32
  make all
}

package() {
  cd "${srcdir}/libpng-${pkgver}"
  make DESTDIR="${pkgdir}" install
  cd "${pkgdir}/usr/i486-mingw32/lib"
  mv libpng14_static.a libpng14.a
  ln -s libpng14.dll.a libpng.dll.a
  ln -s libpng14.a libpng.a
}

# vim:set ts=2 sw=2 et: