# Maintainer: Devin Cofer <ranguvar{AT]archlinux[DOT}us>
# Contributor: CainĂ£ Costa <sryche@archlinux-br.org>
# Contributor: Patrick Bartels <p4ddy.b@gmail.com>
# Contributor: Gimmeapill <gimmeapill[at]gmail[dot]com>
pkgname=fluxbox-git
pkgdesc="A lightweight and highly-configurable window manager (Dev version)"
pkgver=20130113
pkgrel=1
arch=('i686' 'x86_64')
license=('MIT')
url="http://www.fluxbox.org/"
makedepends=('git' 'pkgconfig')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'imlib2' 'fribidi')
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
provides=('fluxbox')
conflicts=('fluxbox')
source=("fluxbox.desktop")
sha256sums=('6986108c908bc9c025d3ded9f4a0027184a732321deb60585f87d485124fada3')
_gitroot="git://git.fluxbox.org/fluxbox.git"
_gitname="fluxbox"
build() {
cd "$srcdir"
msg "Performing source checkout..."
if [ -d "$_gitname" ]; then
cd "$_gitname"
git pull origin
cd ..
else
git clone "$_gitroot"
fi
msg "Source checkout finished."
rm -rf "$_gitname-build"
git clone "$_gitname" "$_gitname-build"
cd "$_gitname-build"
./autogen.sh
./configure --prefix=/usr \
--enable-xft --enable-xinerama \
--enable-imlib2 --enable-nls
make
}
package() {
cd "$srcdir/$_gitname-build"
make DESTDIR="$pkgdir" install
install -D -m644 "$srcdir/fluxbox.desktop" "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
install -D -m644 COPYING "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}