# Maintainer: Limao Luo <luolimao+AUR@gmail.com>
# Contributor: Diego Principe <cdprincipe@gmail.com>
#
# (Added from thunar package)
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Andrew Simmons <andrew.simmons@gmail.com>
_pkgname=thunar
pkgname=$_pkgname-git
pkgver=3018.514a467
pkgrel=1
pkgdesc="New modern file manager for Xfce"
arch=(i686 x86_64)
license=(GPL2)
url=http://$_pkgname.xfce.org
groups=(xfce4-git)
depends=(libexif xfce4-panel)
makedepends=(git xfce4-dev-tools)
provides=($_pkgname=1.6.2)
conflicts=($_pkgname{,-devel})
options=(!libtool)
install=$_pkgname.install
source=(git://git.xfce.org/xfce/$_pkgname)
md5sums=('SKIP')
pkgver(){
cd $srcdir/thunar
echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}
build() {
cd "$srcdir"/"$_pkgname"
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--localstatedir=/var \
--disable-static \
--enable-gio-unix \
--enable-dbus \
--enable-startup-notification \
--enable-gudev \
--enable-exif \
--enable-pcre \
--enable-gtk-doc \
--disable-debug
make
}
package() {
cd "$srcdir"/$_pkgname/
make DESTDIR="$pkgdir" install
sed -i ':x-directory/gnome-default-handler;:d' "$pkgdir"/usr/share/applications/Thunar-folder handler.desktop
}