# Maintainer: Sebastien Luttringer <seblu+arch@seblu.net>
# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
pkgname=istanbul
pkgver=0.2.2
pkgrel=6
pkgdesc='Desktop Session Recorder'
arch=('i686' 'x86_64')
url='http://live.gnome.org/Istanbul'
license=('GPL')
options=('!libtool')
depends=(
'pygtk'
'gnome-python-extras'
'gstreamer0.10'
'gstreamer0.10-python'
'gstreamer0.10-base-plugins'
'python2-gconf'
'python-xlib'
'libxdamage'
'libxext'
'libsm'
)
makedepends=(
'intltool'
'gettext'
)
install=istanbul.install
source=(
"http://zaheer.merali.org/istanbul-$pkgver.tar.bz2"
"http://ftp.de.debian.org/debian/pool/main/i/istanbul/istanbul_0.2.2-8.diff.gz"
'm4.patch'
)
md5sums=(
'8ddcfd5a29dcd10fdafc10af9f66848b'
'26f5e7b1c86e6fc82511787d671803a2'
'24aeec6ca57d88771b9befc46d772af7'
)
sha1sums=(
'f9649990429ef4fb083057685fec723c466ee4b0'
'7aa0d40c59cb64c0a5c7fd28a3cdf4843545a71e'
'0c8a69ff267c1232da91a767ad31ff084fc45b3e'
)
build() {
cd $pkgname-$pkgver
patch -p1 -i ../istanbul_0.2.2-8.diff
while read f; do
patch -Np1 -i debian/patches/$f
done < debian/patches/series
patch -p1 -i ../m4.patch
./configure --prefix=/usr --disable-schemas-install --with-gconf-schema-file-dir=/usr/share/gconf/schemas
make
}
package() {
cd $pkgname-$pkgver
make prefix="$pkgdir/usr" install
install -d -m 755 "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" "$pkgdir"/usr/etc/gconf/schemas/*.schemas
rm -f "$pkgdir"/usr/etc/gconf/schemas/*.schemas
}
# vim:set ts=2 sw=2 ft=sh et: