1. # Maintainer: josephgbr <rafael.f.f1@gmail.com>
  2.  
  3. _pkgbase=libofa
  4. pkgname=lib32-${_pkgbase}
  5. pkgver=0.9.3
  6. pkgrel=1
  7. pkgdesc="An open-source audio fingerprint by MusicIP (32 bit)"
  8. arch=('x86_64')
  9. url="http://code.google.com/p/musicip-libofa/"
  10. license=('GPL2' 'custom')
  11. depends=('lib32-expat' 'lib32-fftw' 'lib32-gcc-libs' "${_pkgbase}")
  12. makedepends=('gcc-multilib' 'lib32-curl')
  13. options=('!libtool')
  14. source=("http://musicip-libofa.googlecode.com/files/${_pkgbase}-${pkgver}.tar.gz"
  15. 'gcc-4.patch'
  16. 'gcc4.3.patch'
  17. 'gcc4.5.patch'
  18. 'fix_ftbfs.diff'
  19. 'http://sites.google.com/site/secondhelper75/gcc-47.patch')
  20. sha1sums=('3dec8e1dcea937f74b4165e9ffd4d4f355e4594a'
  21. 'cb19377d0634c03d2a49cfc61915cec918c341f7'
  22. 'cae08bdc12de923d5e032696702a0530ae6eafc1'
  23. '754d69d66ab46219035ccafeeb3ff62433cca4f2'
  24. 'dfddfb6e9db037f8edce116911855c6732320dca'
  25. '1dd7176c8478431bdc29e748c637f829e7e6ac42')
  26.  
  27. build() {
  28. export CC='gcc -m32'
  29. export CXX='g++ -m32'
  30. export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  31.  
  32. cd "${srcdir}/${_pkgbase}-${pkgver}"
  33.  
  34. patch -p0 -i ${srcdir}/gcc-4.patch
  35. patch -p1 -i ${srcdir}/gcc4.3.patch
  36. patch -p1 -i ${srcdir}/gcc4.5.patch
  37. patch -p1 -i ${srcdir}/gcc-47.patch
  38. #http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=637896
  39. patch -p1 -i ${srcdir}/fix_ftbfs.diff
  40.  
  41. ./configure --prefix=/usr --libdir=/usr/lib32
  42. make
  43. }
  44.  
  45. package() {
  46. cd "${srcdir}/${_pkgbase}-${pkgver}"
  47. make DESTDIR=${pkgdir} install
  48. rm -rf "${pkgdir}/usr/include"
  49. mkdir -p "${pkgdir}/usr/share/licenses"
  50. ln -sf ${_pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  51. }