1. # Maintainer:
  2. # Contributor: M0Rf30
  3. # Contributor: unifiedlinux
  4. # Contributor: CReimer
  5.  
  6. pkgname=cinnamon
  7. pkgver=1.6.7
  8. pkgrel=3
  9. pkgdesc="Linux desktop which provides advanced innovative features and a traditional user experience"
  10. arch=('i686' 'x86_64')
  11. url="http://cinnamon.linuxmint.com/"
  12. license=('GPL2')
  13. depends=('caribou' 'gjs' 'gnome-bluetooth' 'gnome-control-center' 'gnome-panel' 'gnome-session'
  14. 'gnome-settings-daemon' 'gnome-themes-standard' 'gstreamer0.10' 'libgnomekbd' 'muffin-wm'
  15. 'notification-daemon' 'python2-gconf' 'python2-imaging' 'python2-lxml')
  16. makedepends=('gnome-common' 'intltool')
  17. optdepends=('nemo-fm: Official Cinnamon file manager (a Nautilus fork)'
  18. 'nautilus: Official Gnome file manager')
  19. options=('!libtool' '!emptydirs')
  20. install=${pkgname}.install
  21. source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/$pkgname/tarball/$pkgver"
  22. "https://raw.github.com/leigh123linux/$pkgname/master/files/etc/xdg/autostart/${pkgname}-screensaver.desktop"
  23. "https://raw.github.com/leigh123linux/$pkgname/master/files/etc/xdg/autostart/${pkgname}2d-screensaver.desktop")
  24. md5sums=('ea73c6367d43d82c61f977477bf0c08c'
  25. 'd55c079cdc8bec606f510f87b2a6f776'
  26. '5c6af851ab1cf7e9219f11d86353196a')
  27.  
  28. build() {
  29. cd ${srcdir}/linuxmint-Cinnamon*
  30.  
  31. sed -i 's/\ --warn-all\ --warn-error//' src/Makefile.am
  32.  
  33. ./autogen.sh --prefix=/usr \
  34. --sysconfdir=/etc \
  35. --libexecdir=/usr/lib/cinnamon \
  36. --localstatedir=/var \
  37. --disable-static \
  38. --disable-schemas-compile \
  39. --enable-compile-warnings=yes \
  40. --with-session-tracking=systemd
  41. make
  42. }
  43.  
  44. package() {
  45. cd ${srcdir}/linuxmint-Cinnamon*
  46. make DESTDIR="${pkgdir}" install
  47.  
  48. #Run python2 instead of python(3)
  49. sed -i 's/bin\/python/bin\/python2/g' \
  50. "${pkgdir}/usr/bin/$pkgname-extension-tool" \
  51. "${pkgdir}/usr/bin/$pkgname-launcher" \
  52. "${pkgdir}/usr/bin/$pkgname-menu-editor" \
  53. "${pkgdir}/usr/bin/$pkgname-settings" \
  54. "${pkgdir}/usr/share/$pkgname/applets/panel-launchers@$pkgname.org/$pkgname-add-panel-launcher.py"
  55.  
  56. sed -i 's/env python/env python2/g' \
  57. "${pkgdir}/usr/lib/$pkgname-settings/$pkgname-settings.py"
  58.  
  59. install -Dm644 $srcdir/${pkgname}-screensaver.desktop ${pkgdir}/etc/xdg/autostart/${pkgname}-screensaver.desktop
  60. install -Dm644 $srcdir/${pkgname}2d-screensaver.desktop ${pkgdir}/etc/xdg/autostart/${pkgname}2d-screensaver.desktop
  61. }