pkgname=nvidia-beta-ck
pkgver=290.06
_extramodules=extramodules-3.1-ck
_kernver="$(cat /lib/modules/${_extramodules}/version)"
pkgrel=2
_pkgdesc="Beta nVidia drivers for linux-ck."
arch=('i686' 'x86_64')
url="http://www.nvidia.com/"
depends=('linux-ck>=3.1' 'linux-ck<3.2' "nvidia-utils=${pkgver}")
makedepends=('linux-ck-headers>=3.1' 'linux-ck-headers<3.2')
conflicts=('nvidia-96xx-all' 'nvidia-173xx-all' 'nvidia-ck-stable' 'nvidia-ck')
license=('custom')
options=(!strip)
install=$pkgname.install
if [ "$CARCH" = "i686" ]; then
_arch='x86'
_pkg="NVIDIA-Linux-${_arch}-${pkgver}"
source=("http://us.download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
md5sums=('e7d718a8f2bbfdd1a479e2e01db84240')
elif [ "$CARCH" = "x86_64" ]; then
_arch='x86_64'
_pkg="NVIDIA-Linux-${_arch}-${pkgver}-no-compat32"
source=("http://us.download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
md5sums=('742bc411b475f9dab68ffd1688fd3316')
fi
build() {
cd "${srcdir}"
sh ${_pkg}.run --extract-only
cd ${_pkg}/kernel
make SYSSRC=/lib/modules/"${_kernver}/build" module
}
package() {
install -D -m644 "${srcdir}/${_pkg}/kernel/nvidia.ko" \
"${pkgdir}/lib/modules/${_extramodules}/nvidia.ko"
install -d -m755 "${pkgdir}/etc/modprobe.d"
echo "blacklist nouveau" >> "${pkgdir}/etc/modprobe.d/nouveau_blacklist_ck.conf"
sed -i -e "s/EXTRAMODULES='.*'/EXTRAMODULES='${_extramodules}'/" "${startdir}/nvidia-ck.install"
gzip "${pkgdir}/lib/modules/${_extramodules}/nvidia.ko"
}