# Maintainer: t3ddy <t3ddy1988 "at" gmail {dot} com>
# Contributor: Lex Rivera aka x-demon <aur@x-demon.org>
# Contributor: Det <nimetonmaili at gmail a-dot com>
# Contributor: ruario
pkgname=google-chrome-beta
pkgver=21.0.1180.77 # Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Beta%20updates
pkgrel=1
pkgdesc="An attempt at creating a safer, faster, and more stable browser (Beta Channel)"
arch=('i686' 'x86_64')
url="http://www.google.com/chrome"
license=('custom:chrome')
depends=('alsa-lib' 'gconf' 'gtk2' 'hicolor-icon-theme' 'libpng' 'libxslt' 'libxss' 'nss' 'ttf-dejavu' 'xdg-utils')
optdepends=('kdebase-kdialog: needed for file dialogs in KDE' 'openssl098: needed for built-in flash-plugin to work')
provides=("google-chrome=$pkgver")
conflicts=('google-chrome')
install=${pkgname}.install
_channel='beta'
if [ "$CARCH" = "i686" ]; then
_arch='i386'
md5sums=('fc4d19799e1bfaffd488a7db2d081faf')
elif [ "$CARCH" = "x86_64" ]; then
_arch='amd64'
md5sums=('08a4ea0fe81edec22b1fd3bc43cf1d25')
fi
source=("https://dl.google.com/linux/direct/google-chrome-${_channel}_current_${_arch}.deb")
package() {
msg "Extracting the data.tar.lzma"
bsdtar -xf data.tar.lzma -C "$pkgdir"
msg2 "Done!"
msg "Preparing install"
install -d "$pkgdir"/{opt,usr/{bin,share/applications}}
msg2 "Done preparing!"
msg "Actual installation"
mv "$pkgdir/opt/google/chrome/google-chrome.desktop" "$pkgdir/usr/share/applications"
# Remove 64-bit executable from 32-bit installation
if [ "$CARCH" = "i686" ]; then
rm -f "$pkgdir/opt/google/chrome/nacl_irt_x86_64.nexe"
fi
# Udev workaround
ln -s /usr/lib/libudev.so.1 "$pkgdir/opt/google/chrome/libudev.so.0"
# Symlinking icons to /usr/share/icons/hicolor/
for i in 16x16 22x22 24x24 32x32 48x48 64x64 128x128 256x256; do
mkdir -p "$pkgdir/usr/share/icons/hicolor/$i/apps/"
ln -s /opt/google/chrome/product_logo_${i/x*}.png "$pkgdir/usr/share/icons/hicolor/$i/apps/google-chrome.png"
done
msg2 "Installation finished!"
}