group = 'se.accenture.assembly'

buildscript {
    dependencies {
        classpath 'com.intershop.build.gradle:ish-assembly'
        classpath 'com.intershop.build.gradle:plugin-tests'
        classpath group: 'com.intershop.build.release', name: 'intershop-buildinfo-plugin', version: '2.2.6'
    }
}

apply plugin: 'ish-assembly'
apply plugin: 'ish-assembly-branding'
apply plugin: 'buildinfo'

assembly {
    inheritFrom('com.intershop.assembly:commerce_management_b2x') {
        includeArtifacts type:['deploy-gradle', 'deploy-settings-gradle', 'staging-properties']
    }

    cartridges {
		def electrolyxCartridges = [
            'electrolyx2017_common',
            'electrolyx2017_app_sf',
			'electrolyx2017_backoffice'
        ]
        include(*(electrolyxCartridges.collect {"se.accenture.electrolyx2017:$it"}), in:[development, test, production])

        def storefrontCartridges = [
        	'app_sf_responsive',
            'app_sf_responsive_cm',
            'app_sf_responsive_b2c',
            'app_sf_responsive_smb',
            'as_responsive',
            'app_sf_responsive_b2b',
            'app_sf_responsive_costcenter',
            'as_responsive_b2b'
        ]
        include(*(storefrontCartridges.collect {"se.brightstep.is76_demob2x:$it"}), in:[development, test, production])

        def initCartridges = [
        	'demo_responsive',
            'demo_responsive_catalog',
            'demo_responsive_content',
            'demo_responsive_search',
            'demo_responsive_b2b',
            'demo_responsive_ocst'
        ]
        include (*(initCartridges.collect {"se.brightstep.is76_demob2x:$it"}), in: init)

		// version WITHOUT the Training cartridges
        order = listFromAssembly('com.intershop.assembly:commerce_management_b2x') + storefrontCartridges + electrolyxCartridges + initCartridges

		}

    extraAttributes = [
            'productName': 'Intershop Training Environment  2017',
            'copyrightOwner': 'Accenture Interactive',
            'copyrightFrom': '2017'
        ]
}

assemblyBuild {
    database {
        // inherit('com.intershop.assembly:commerce_management_b2x')
        // initCartridges = ['demo_responsive', 'demo_responsive_content', 'demo_responsive_search', 'demo_responsive_b2b']
    }
}

dependencies {
    testCompile 'com.intershop.build.gradle:ish-common'
    testCompile 'com.intershop.build.gradle:ish-assembly-test'

    // selenium web drivers
    remoteTestCompile "org.seleniumhq.selenium:selenium-support:2.47.+"
	remoteTestCompile "org.seleniumhq.selenium:selenium-chrome-driver:2.47.+"
	remoteTestCompile ("com.codeborne:phantomjsdriver:1.2.+") {
		transitive = false
	}
}

configurations.all {
    // TODO Guice update required
    exclude group: 'asm', module: 'asm'

}

gebConfiguration {
    webDrivers {
        phantomJsDriver {
            environments {
                phantomJsPC {check=true}
            }

            download {
                linux {
                    url = 'https://bitbucket.org/ariya/phantomjs/downloads/phantomjs-1.9.7-linux-x86_64.tar.bz2'
                    archiveType = 'tar'
                    webDriverDir = 'phantomjs-1.9.7-linux-x86_64'
                    webDriverExec = 'bin/phantomjs'
                }
                windows {
                    url = 'https://bitbucket.org/ariya/phantomjs/downloads/phantomjs-1.9.7-windows.zip'
                    archiveType = 'zip'
                    webDriverDir = 'phantomjs-1.9.7-windows'
                    webDriverExec = 'phantomjs.exe'
                }
            }
        }

        chromeDriver {
            environments {
                chromePC
                chromeTablet
            }

            download {
                linux {
                    url = 'http://chromedriver.storage.googleapis.com/2.20/chromedriver_linux64.zip'
                    archiveType = 'zip'
                    webDriverExec = 'chromedriver'
                }
                windows {
                    url = 'http://chromedriver.storage.googleapis.com/2.20/chromedriver_win32.zip'
                    archiveType = 'zip'
                    webDriverExec = 'chromedriver.exe'
                }
            }
        }
    }
}

/***********************************************************************************************************************
 *
 * Currently the gradle tools do not provide a task for rebuilding the search indexes. But these it required for inSPIRED
 * storefront tests. So this is workaround for solving this problem temporary.
 *
 ***********************************************************************************************************************/
buildscript {
    dependencies {
        classpath 'com.github.groovy-wslite:groovy-wslite:1.+'
    }
}

task 'buildSearchIndex' {
    def hostName    = remoteTest.env.hostName
    def port        = remoteTest.env.webserverPort
    def adminUser   = remoteTest.env.adminUser?: 'admin'
    def adminPwd    = remoteTest.env.adminPwd?:  '!InterShop00!'

    def url = "http://${hostName}:${port}/INTERSHOP/rest/BOS/SMC/-/domains/SLDSystem/jobs"

    def jobStatus = { job ->
        def client = new wslite.rest.RESTClient("${url}/${job}")
        client.authorization = new wslite.http.auth.HTTPBasicAuthorization(adminUser, adminPwd)
        def response = client.get()
        return response.json.status
    }

    def triggerJob = {job ->
        def client = new wslite.rest.RESTClient("${url}/${job}")
        client.authorization = new wslite.http.auth.HTTPBasicAuthorization(adminUser, adminPwd)

        try {
            def responseTrigger = client.put() {
                json type: 'job', status: 'RUNNING'
            }
        } catch(wslite.http.HTTPClientException ex) {
            logger.warn(ex.message, ex)
        }

        def maxTry = 60
        while (maxTry-- > 0 && "READY" != jobStatus(job)) {
            sleep 5000
        }
    }

    doFirst {
        triggerJob("Rebuild%20Search%20Indexes")
        triggerJob("Update%20Product%20Assignments")
        triggerJob("Rebuild%20Search%20Indexes")
    }
}


tasks.buildSearchIndex.mustRunAfter tasks.startWebserver
tasks.buildSearchIndex.mustRunAfter tasks.startNodemanager
tasks.publish.mustRunAfter tasks.remoteTest
tasks.each { t ->
    if (t.name ==~ /geb.*Test/) {
        t.dependsOn tasks.buildSearchIndex
        t.mustRunAfter tasks.dbinit
    }
}