triplem

#Contributor: Markus M. May <mmay AT javafreedom DOT org>
pkgname=hudson
pkgver=1.392
pkgrel=1
_wrapver=3.4.1
pkgdesc="Extensible Continuous Integration Server."
url="http://hudson-ci.org"
arch=('i686' 'x86_64')
license=('MIT')
depends=('java-environment')
optdepends=('apache: a full featured webserver'
            'maven: a java project management and project comprehension tool')

conflicts=('java-hudson' 'hudson')
provides=('hudson')
options=(!strip !docs )

install=java-hudson.install
source=(http://updates.hudson-labs.org/download/war/${pkgver}/hudson.war
        http://wrapper.tanukisoftware.org/download/$_wrapver/wrapper-delta-pack-$_wrapver.tar.gz
        'wrapper.conf'
        'hudson')

noextract=(hudson.war)

md5sums=('d46e7f74d6c13c08a00664101e992ef0'
         'a4eb5f779b09fdba71c8b94450169bcc'
         'ae20867fc94e77c15ec861356cc5283a'
         '4a40d070e75135ef9f502b75bccbe11e')

package() {
  cd ${srcdir}

  # Create directory
  install -dm755 $pkgdir/opt/hudson
  install -dm755 $pkgdir/opt/hudson/bin
  install -dm755 $pkgdir/opt/hudson/lib
  install -dm755 $pkgdir/opt/hudson/conf
  install -dm755 $pkgdir/opt/hudson/logs
  install -dm755 $pkgdir/opt/hudson/tmp

  # prepare wrapper
  if [ $CARCH = 'x86_64' ]; then
    install -Dm755  $srcdir/wrapper-delta-pack-$_wrapver/bin/wrapper-linux-x86-64    $pkgdir/opt/hudson/bin/wrapper
    install -Dm644 $srcdir/wrapper-delta-pack-$_wrapver/lib/libwrapper-linux-x86-64.so $pkgdir/opt/hudson/lib/
  elif [ $CARCH = 'i686' ]; then
    install -Dm755  $srcdir/wrapper-delta-pack-$_wrapver/bin/wrapper-linux-x86-32 $pkgdir/opt/hudson/bin/wrapper
    install -Dm644  $srcdir/wrapper-delta-pack-$_wrapver/lib/libwrapper-linux-x86-32.so $pkgdir/opt/hudson/lib/
  fi
   install -Dm644 $srcdir/wrapper-delta-pack-$_wrapver/lib/wrapper.jar $pkgdir/opt/hudson/lib/
   install -Dm644 $srcdir/wrapper-delta-pack-$_wrapver/logs/wrapper.log $pkgdir/opt/hudson/logs/

   install -Dm644 $srcdir/hudson.war $pkgdir/opt/hudson/lib/
   install -Dm644 $srcdir/wrapper.conf $pkgdir/opt/hudson/conf/
   install -Dm755 $srcdir/hudson $pkgdir/opt/hudson/bin/

   mkdir -p $pkgdir/var/lib/hudson
   mkdir -p $pkgdir/var/run/hudson

}