#!/usr/bin/perl -w
#
# check_red5 - Nagios check plugin for Red5
#
# Copyright (c) 2013 Revolution Linux - Pascal Bernier <pb@rlnx.com>
#

use POSIX;
use Getopt::Long;
use vars qw($opt_P $opt_V $opt_h $opt_H $opt_W $opt_a $verbose);
use vars qw($PROGNAME);
use lib "/usr/lib/nagios/plugins";
use utils qw($TIMEOUT %ERRORS &print_revision &support &usage);
use Socket qw(:all);

sub print_help();
sub print_usage();

$PROGNAME = "check_red5";

$ENV{'PATH'}='';
$ENV{'BASH_ENV'}='';
$ENV{'ENV'}='';

Getopt::Long::Configure('bundling');
GetOptions
    ("v"   => \$verbose, "verbose"  => \$verbose,
     "P=s" => \$opt_P, "port=s"     => \$opt_P,
     "V"   => \$opt_V, "version"    => \$opt_V,
     "h"   => \$opt_h, "help"       => \$opt_h,
     "H=s" => \$opt_H, "host=s" => \$opt_H,);

if ($opt_V) {
    print_revision($PROGNAME,'0.1');
    exit $ERRORS{'OK'};
}

if ($opt_h) {
    print_help();
    exit $ERRORS{'OK'};
}

# Options checking

($opt_H) || ($opt_H = shift) || usage("ERROR : Host name not specified\nUse -h for more info\n");
my $host = $opt_H if ($opt_H =~ /^([-_.A-Za-z0-9 ]+\$?)$/);
($host) || usage("ERROR Invalid host: $opt_H\n");

($opt_P) || ($opt_P = shift) || usage("ERROR : Port not specified\nUse -h for more info\n");
my $port = $opt_P if (isdigit $opt_P);
($port) || usage("ERROR Invalid port: $opt_P\n");

my $packedip = gethostbyname($host) || usage("ERROR : Unable to resolve $host\n");
#my $ip = inet_ntoa($packedip);

# End of options checking

my $state = "OK";
my $answer = "RED5 OK\n";

# Just in case of problems, let's not hang Nagios
$SIG{'ALRM'} = sub {
    $answer = "RED5 UNKNOWN - Bad arguments or no answer from client\n";
    $state = "UNKNOWN";
    print $answer;
    print "$state\n" if ($verbose);
    exit $ERRORS{$state};
};
alarm($TIMEOUT);

# Phase 1 open a socket
my $address = sockaddr_in($port, $packedip);
socket(SOCK, AF_INET, SOCK_STREAM, IPPROTO_TCP);
my $connection = connect(SOCK, $address);

if (!defined $connection) {
    $state = "CRITICAL";
    $answer = "RED5 CRITICAL - Connection refused\n";
}

# Phase 2 version handshake
# See docs for handshake : https://www.adobe.com/content/dam/Adobe/en/devnet/rtmp/pdf/rtmp_specification_1.0.pdf

if ($connection) {
    my @c0 = qw(01);
    red5_send_hex(\@c0);

    my @c1 = qw(00 00 00 00); # time - 4 bytes
    push @c1, qw(00 00 00 00); # zero - 4 bytes
    for (1..1528) { push @c1, '99';}
    red5_send_hex(\@c1);

    my $s0 = red5_recv(1);
    if ($s0 ne "\x03") {
        $state = "CRITICAL";
        $answer = "RED5 CRTICIAL - Handshake failed\n";
    }

}

# Turn off alarm
alarm(0);

print $answer;
print "$state\n" if ($verbose);

# restart red5 if critical
if ($state eq "CRITICAL") {
system("/usr/bin/sudo /usr/local/bin/restart_red5.sh &");
}

exit $ERRORS{$state};

sub red5_send_hex
{
    my ($ref_hex_array) = @_;
    my $send_str = '';
    foreach (@$ref_hex_array)
    {
        my $one_byte = '0x'.$_;
        $send_str.= pack('C', oct($one_byte));
    }
    my $sent = syswrite(SOCK, $send_str);
    return $sent;
}

sub red5_recv
{
    my ($wanted_length, $time_out) = @_;
    return unless $wanted_length =~ /^[1-9][\d]*$/;
    $time_out = 3 unless $time_out;

    my $start_time = time;
    my $bytes = '';
    while(1)
    {
        if (time - $start_time >= $time_out)
        {
            print "func: red5_recv(), timeout for $time_out Seconds\n";
            return '';
        }
        my $buf = '';
        my $success_length = sysread(SOCK, $buf, $wanted_length);
        next unless $success_length; # for no-block IO
        $bytes .= $buf;
        $wanted_length = $wanted_length - $success_length;
        last if $wanted_length <= 0;
    }
    return $bytes;
}


sub print_usage() {
    print "Usage: $PROGNAME -H <host> -P <port>\n";
}

sub print_help() {
    print_revision($PROGNAME,'0.1');
    print "\nPerl Check RED5 plugin for Nagios\n";
    print "\nCopyright (c) Revolution Linux 2013 - Pascal Bernier <pb\@rlnx.com>\n\n";
    print_usage();
    print "\n-h, --help\n";
    print "    Help\n";
    print "-V, --version\n";
    print "    Version of this script\n";
    print "-H, --hostname=HOST\n";
    print "    Hostname of the server\n";
    print "-P, --port=INTEGER\n";
    print "    Port to be used to connect to.\n\n";
    #support();
}