# Maintainer: Peter Strapp <peter at strapp.co.uk>
# Contributor: Lucas H. Gabrielli <heitzmann@gmail.com>

_base=pigpio
pkgname=python-pigpio-git
pkgdesc="C library for the Raspberry which allows control of the General Purpose Input Outputs (GPIO)"
pkgver=r121.2bd75cd
pkgrel=1
url="http://abyz.co.uk/rpi/pigpio/"
license=('custom:UNLICENSE')
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
depends=('glibc')
source=("${_base}::git+https://github.com/joan2937/pigpio.git")
options=(!emptydirs)
sha1sums=('SKIP')

pkgver() {
  cd "$_base"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$_base"
  sed -e '/ldconfig/d' -i Makefile
  sed -e 's|setup.py install|setup.py install --root="'"${pkgdir}"'/"|g' -i Makefile
  sed -e 's|/usr/local|/usr|g' -i Makefile
  sed -e 's|/usr/local|/usr|g' -i MakeRemote
  sed -e 's|/usr/local|/usr|g' -i util/Findpigpio.cmake
}

build() {
  cd "$_base"
  make
}

package() {
  cd "$_base"
  make DESTDIR="$pkgdir" install

    mkdir "${pkgdir}/usr/share"
    mv "${pkgdir}/usr/man" "${pkgdir}/usr/share/man"

    install -Dm644 "${srcdir}/${_base}/UNLICENCE" "${pkgdir}/usr/share/licenses/${pkgname}/UNLICENSE"
}