# Maintainer: Idares <idares@seznam.cz>
# Contributor: Enrico Morelli <morelli@cerm.unifi.it>
# Contributor: Vadym Abramchuk <abramm@gmail.com>
# Contributor: karol_007 <karol.blazewicz@gmail.com>

pkgname=zabbix-agent
pkgver=2.0.5
pkgrel=1
pkgdesc="Software for monitoring of your applications, network and servers."
arch=('i686' 'x86_64')
url="http://www.zabbix.com"
license=('GPL')
backup=('etc/zabbix/zabbix_agent.conf'
        'etc/zabbix/zabbix_agentd.conf'
        )
install="zabbix-agent.install"
source=("http://downloads.sourceforge.net/project/zabbix/ZABBIX%20Latest%20Stable/$pkgver/zabbix-$pkgver.tar.gz"
        "zabbix-agentd"
        "zabbix-agent.install"
        "zabbix-agentd.service"
        )

build() {
    cd $srcdir/zabbix-$pkgver
    ./configure \
        --prefix=/usr \
        --sysconfdir=/etc/zabbix \
        --enable-agent
    make
}

package() {
    cd $srcdir/zabbix-$pkgver
    make DESTDIR=$pkgdir install

    install -d -m0750 $pkgdir/var/run/zabbix
    install -d -m0750 $pkgdir/var/log/zabbix

    install -D -m0755 $startdir/src/zabbix-agentd $startdir/pkg/etc/rc.d/zabbix-agentd
    install -D -m0644 $srcdir/zabbix-agentd.service $pkgdir/usr/lib/systemd/system/zabbix-agentd.service

    # change pid file location
    sed -i 's:# PidFile=.*:PidFile=/var/run/zabbix/zabbix_agentd.pid:' $pkgdir/etc/zabbix/zabbix_agentd.conf
}

md5sums=('0c0721c31889b63bce9aa556bcb927e8'
         '3a3830fa4cd239cf8631c33e3fa69d13'
         'ebe9f39104737605ca76b3dd490fddff'
         'b3b9487aadc6deaefce56a495f4dbb5d')
sha1sums=('7798e5d69e0a301be3f014cc0d800c3ee153faa0'
          '0d0d2a22bb3985b241c94c2bf45070aba534dfa0'
          'ac7e22306e188b87c539f85750dfac2ca1e5c28a'
          '7b0a18c648e3a11cf5e6bb896a38213dcdb609dc')