nss-pam-ldapd

# Maintainer: Kaiting Chen <kaiting.chen@kiwilight.com>
# Contributor: Cheer Xiao <xiaqqaix.at.gmail.com>
# Contributor: Thiago Kenji Okada <thiago DOT mast3r AT gmail DOT com>

pkgname='nss-ldapd'
_pkgname='nss-pam-ldapd'
pkgver='0.8.11'
pkgrel='1'
pkgdesc='LDAP module for NSS and PAM'
arch=('i686' 'x86_64')
url="http://arthurdejong.org/$_pkgname/"
license=('LGPL2.1')
depends=('krb5' 'pam' 'libldap' 'libsasl')

backup=('etc/nslcd.conf')

sha1sums=('b221c603de5162ca2411a7e883ab21711d62db97'
         '56739b0084442bd151e775ed3e03836ff2e4c400'
         '65b452d696ed93e410378d087d3b2ec9a76bed8d')
source=("$url$_pkgname-$pkgver.tar.gz"
        'nslcd.rc.d'
        'nslcd.service')
install=nss-ldapd.install

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --libdir=/usr/lib \
    --localstatedir=/var \
    --enable-sasl \
    --with-pam-seclib-dir=/usr/lib/security \
    --with-nslcd-pidfile=/run/nslcd.pid \
    --with-nslcd-socket=/run/nslcd.sock
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
  install -Dm755 $srcdir/nslcd.rc.d $pkgdir/etc/rc.d/nslcd
  install -Dm755 $srcdir/nslcd.service $pkgdir/usr/lib/systemd/system/nslcd.service
}