st-hg PKGBUILD

# Maintainer: Scytrin dai Kinthra <scytrin@gmail.com>
# Contributor: Devin J. Pohly <djpohly+arch@gmail.com>
pkgname=st-hg
pkgver=149
pkgrel=1
pkgdesc="A simple virtual terminal emulator for X"
arch=('i686' 'x86_64')
url="http://st.suckless.org/"
license=('MIT')
depends=('libx11')
makedepends=('ncurses')
# Uncomment to use your own config.h
#source=(config.h)
#md5sums=(...generate your own...)

_hgroot="http://hg.suckless.org/"
_hgrepo="st"

build() {
  cd "$srcdir"
  msg "Connecting to Mercurial server...."

  if [ -d $_hgrepo ] ; then
    cd $_hgrepo
    hg pull -u || return 1
    msg "The local files are updated."
  else
    hg clone $_hgroot $_hgrepo || return 1
  fi

  msg "Mercurial checkout done or server timeout"
  msg "Starting make..."

  rm -rf "$srcdir/$_hgrepo-build"
  cp -r "$srcdir/$_hgrepo" "$srcdir/$_hgrepo-build"
  cd "$srcdir/$_hgrepo-build"

  # Uncomment to use your own config.h
  #cp "$srcdir/config.h" . || return 1

  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11 || return 1
}

package() {
  cd "$srcdir/$_hgrepo-build"

  install -d "$pkgdir/usr/share/terminfo" || return 1
  make PREFIX=/usr DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install || return 1
  install -m644 -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE" || return 1
  install -m644 -D README "$pkgdir/usr/share/doc/$pkgname/README" || return 1
}

# vim:set ts=2 sw=2 et: