accerciser 3.3.1-1 PKGBUILD

pkgname=accerciser
pkgver=3.3.1
pkgrel=1
pkgdesc="Interactive Python accessibility explorer for the GNOME desktop"
arch=('any')
url="http://live.gnome.org/Accerciser"
license=('BSD')
depends=('gtk3>=3.1.13'
     'python2-gobject>=2.90.3'
     'python2>=2.4'
     'pygtk>=2.8'
         'ipython2'
         'glib2>=2.10'
         'at-spi2-core>=2.1.5'
         'pyatspi>=1.9.0'
         'dconf'
         'hicolor-icon-theme')
makedepends=('gnome-doc-utils' 'intltool' 'gobject-introspection')
install=accerciser.install
source=(http://ftp.gnome.org/pub/GNOME/sources/accerciser/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('0abc560d243430b0a3f4ad0fbeab1e2ce0c7329d3406f9c395eed843d1238c70')

build () {
  cd "$srcdir/$pkgname-$pkgver"

  # Change hard coded references of python to python2
  sed -i -e 's|env python|env python2|' src/accerciser.in
  sed -i -e 's|bin/python|bin/python2|' plugins/*.py

  PYTHON=python2 ./configure --prefix=/usr --sysconfdir=/etc \
        --disable-schemas-compile
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="${pkgdir}" install
  install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}"
}